games-fps/ssamtse-1_beta1-r1.ebuild

ssamtse-1_beta1-r1.ebuild (text/plain), 4.03 KB, created by Jared B. on 2012-09-15 04:23:40 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit cdrom eutils versionator games unpacker

# MY_PV will be e.g. "beta1"
MY_PV=$(get_version_component_range 2-2)
SZ="ftp://ftp.planetmirror.com/pub/seriouszone"
SH_FILE="${PN}-${MY_PV}.sh.bin"

DESCRIPTION="Serious Sam: The Second Encounter"
HOMEPAGE="http://www.croteam.com/
	http://www.seriouszone.com/"
SRC_URI="${SZ}/${SH_FILE}
	http://icculus.org/betas/ssam/${SH_FILE}
	maps? (
		${SZ}/ssse/maps/militarydecay.zip
		${SZ}/ssse/maps/alpineii.zip
		${SZ}/ssse/maps/otmosis.zip
		)
	models? (
		${SZ}/ssse/models/SeriousSamantha.zip
		${SZ}/ssse/models/ronaldmcdonald.zip
		${SZ}/ssse/models/smoothsam.zip
		${SZ}/ssse/models/sleepysam.zip
		${SZ}/ssse/models/adventurousash.zip
		)
	"

LICENSE="LOKI-EULA"
SLOT="0"
KEYWORDS="amd64 ~x86"
RESTRICT="mirror strip"
IUSE="maps models"

RDEPEND="virtual/opengl
	media-libs/libsdl"
DEPEND=">=app-arch/unshield-0.6
	maps? ( app-arch/unzip )
	models? ( app-arch/unzip )
	"

S=${WORKDIR}

pkg_setup() {
	games_pkg_setup

	cdrom_get_cds "Install/SE1_00.gro"
}

src_unpack() {
	mkdir Levels Mods

	unpack_makeself "${SH_FILE}"
	unpack ./setupstuff.tar.gz
	unpack ./bins.tar.bz2

	local f
	if use maps ; then
		for f in otmosis alpineii militarydecay ; do
			unpack "${f}.zip"
		done
	fi

	if use models ; then
		for f in adventurousash sleepysam smoothsam ronaldmcdonald SeriousSamantha ; do
			unpack "${f}.zip"
		done
	fi
}

src_prepare() {
	# Switch to dynamic executable - runs at sane speeds on modern hardware
	sed -i -e 's;exec "./ssam_lnx";exec "./ssam_lnx.dynamic";' bin/${PN} \
		|| die "dynamic binary update failed"
}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/${PN}

	einfo "Copying from ${CDROM_ROOT}"
	insinto "${dir}"
	doins -r "${CDROM_ROOT}"/Install/* || die "doins CD failed"

	# Correct paths of copied resource files
	mv "${D}/${dir}"/Locales/eng/Controls/* "${D}/${dir}"/Controls/
	mv "${D}/${dir}"/Locales/eng/Data/Var/* "${D}/${dir}"/Data/Var/
	mv "${D}/${dir}"/Locales/eng/Demos/* "${D}/${dir}"/Demos/
	mv "${D}/${dir}"/Locales/eng/Help/* "${D}/${dir}"/Help/
	mv "${D}/${dir}"/Locales/eng/Mods/Warped/Scripts/Addons/WarpedTweak.des "${D}/${dir}"/Mods/Warped/Scripts/Addons/
	mv "${D}/${dir}"/Locales/eng/Mods/Warped/Readme.html "${D}/${dir}"/Mods/Warped/
	mv "${D}/${dir}"/Locales/eng/Mods/*.des "${D}/${dir}"/Mods/
	mv "${D}/${dir}"/Locales/eng/Scripts/Addons/* "${D}/${dir}"/Scripts/Addons/
	mv "${D}/${dir}"/Locales/eng/Scripts/CustomOptions/* "${D}/${dir}"/Scripts/CustomOptions/
	mv "${D}/${dir}"/Locales/eng/Scripts/NetSettings/* "${D}/${dir}"/Scripts/NetSettings/
	rm -rf "${D}/${dir}"/Locales

	# The data CABs contain optional multiplayer maps in the "Levels" directory
	einfo "Extracting additional levels"
	unshield x "${D}/${dir}"/data1.cab >/dev/null || die "unshield data1.cab failed"
	rm "${D}/${dir}"/data?.cab

	# Correct paths of extracted levels
	mv Levels/Levels/LevelsMP/* Levels/LevelsMP/
	rm -rf Levels/Levels
	mv Levels/LevelsMP/Technology/* Levels/
	rmdir Levels/LevelsMP/Technology
	mv Levels/Mods/Warped/ Mods/
	rmdir Levels/Mods/

	doins -r Bin Data Levels Mods *.txt README* \
		|| die "doins main failed"

	if use maps || use models ; then
		doins *.gro || die
	fi

	if use models ; then
		doins -r Models || die
	fi

	# Install bins last to ensure they are marked executable
	exeinto "${dir}"
	doexe bin/${PN} || die
	exeinto "${dir}"/Bin
	doexe Bin/{ssam_lnx*,*.so} || die

	# Remove useless Windows files
	rm -rf "${D}/${dir}/Bin"/{*.exe,*.dll,*.DLL,GameSpy}

	dodoc README.linux

	newicon ssam.xpm ${PN}.xpm || die
	games_make_wrapper ${PN} ./${PN} "${dir}" "${dir}"
	make_desktop_entry ${PN} "Serious Sam - Second Encounter" ${PN}

	# Ensure that file datestamps from the CD are sane
	find "${D}/${dir}" -exec touch '{}' \;

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "The warning regarding 'XiG-SUNDRY-NONSTANDARD missing' is harmless."
	elog "Important information about the Linux port is at:"
	elog "   http://files.seriouszone.com/download.php?fileid=616"
	echo
}