[patch] patch for timezone-data-2012e.ebuild

timezone-data-2012e.ebuild.patch (text/plain), 3.38 KB, created by Christoph Junghans (RETIRED) on 2012-09-03 03:49:57 UTC

--- timezone-data-2012e.ebuild.orig	2012-09-02 21:39:17.000000000 -0600
+++ timezone-data-2012e.ebuild	2012-09-02 21:29:13.000000000 -0600
@@ -2,6 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 # $Header: /var/cvsroot/gentoo-x86/sys-libs/timezone-data/timezone-data-2012e.ebuild,v 1.1 2012/08/03 15:49:09 vapier Exp $
 
+EAPI=4
+
 inherit eutils toolchain-funcs flag-o-matic
 
 code_ver=${PV}
@@ -15,15 +17,14 @@
 
 LICENSE="BSD public-domain"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
 IUSE="nls elibc_FreeBSD elibc_glibc"
 
 RDEPEND="!<sys-libs/glibc-2.3.5"
 
 S=${WORKDIR}
 
-src_unpack() {
-	unpack ${A}
+src_prepare() {
 	epatch "${FILESDIR}"/${PN}-2008h-makefile.patch
 	tc-is-cross-compiler && cp -pR "${S}" "${S}"-native
 }
@@ -39,36 +40,36 @@
 	# Makefile uses LBLIBS for the libs (which defaults to LDFLAGS)
 	# But it also uses LFLAGS where it expects the real LDFLAGS
 	emake \
-		LDLIBS="${LDLIBS}" \
-		|| die "emake failed"
+		DESTDIR="${EPREFIX}" \
+		LDLIBS="${LDLIBS}"
 	if tc-is-cross-compiler ; then
 		emake -C "${S}"-native \
 			CC=$(tc-getBUILD_CC) \
 			CFLAGS="${BUILD_CFLAGS}" \
 			LDFLAGS="${BUILD_LDFLAGS}" \
 			LDLIBS="${LDLIBS}" \
-			zic || die
+			zic
 	fi
 }
 
 src_install() {
 	local zic=""
 	tc-is-cross-compiler && zic="zic=${S}-native/zic"
-	emake install ${zic} DESTDIR="${D}" || die
-	rm -rf "${D}"/usr/share/zoneinfo-leaps
+	emake install ${zic} DESTDIR="${D}${EPREFIX}"
+	rm -rf "${ED}"/usr/share/zoneinfo-leaps
 	dodoc README Theory
 	dohtml *.htm
 }
 
 pkg_config() {
 	# make sure the /etc/localtime file does not get stale #127899
-	local tz src etc_lt="${ROOT}etc/localtime"
+	local tz src etc_lt="${EROOT}etc/localtime"
 
 	if has_version '<sys-apps/baselayout-2' ; then
-		src="${ROOT}etc/conf.d/clock"
+		src="${EROOT}etc/conf.d/clock"
 		tz=$(unset TIMEZONE ; source "${src}" ; echo ${TIMEZONE-FOOKABLOIE})
 	else
-		src="${ROOT}etc/timezone"
+		src="${EROOT}etc/timezone"
 		if [[ -e ${src} ]] ; then
 			tz=$(sed -e 's:#.*::' -e 's:[[:space:]]*::g' -e '/^$/d' "${src}")
 		else
@@ -84,7 +85,7 @@
 			# if /etc/localtime is a symlink somewhere, assume they
 			# know what they're doing and they're managing it themselves
 			if [[ ! -L ${etc_lt} ]] ; then
-				cp -f "${ROOT}"/usr/share/zoneinfo/Factory "${etc_lt}"
+				cp -f "${EROOT}"/usr/share/zoneinfo/Factory "${etc_lt}"
 				elog "Setting ${etc_lt} to Factory."
 			else
 				elog "Assuming your ${etc_lt} symlink is what you want; skipping update."
@@ -95,14 +96,14 @@
 		return 0
 	fi
 
-	if [[ ! -e ${ROOT}/usr/share/zoneinfo/${tz} ]] ; then
-		elog "You have an invalid TIMEZONE setting in ${src}"
+	if [[ ! -e ${EROOT}/usr/share/zoneinfo/${tz} ]] ; then
+		elog "You have an invalid TIMEZONE setting in ${EPREFIX}${src}"
 		elog "Your ${etc_lt} has been reset to Factory; enjoy!"
 		tz="Factory"
 	fi
-	einfo "Updating ${etc_lt} with ${ROOT}usr/share/zoneinfo/${tz}"
+	einfo "Updating ${etc_lt} with ${EROOT}usr/share/zoneinfo/${tz}"
 	[[ -L ${etc_lt} ]] && rm -f "${etc_lt}"
-	cp -f "${ROOT}"/usr/share/zoneinfo/"${tz}" "${etc_lt}"
+	cp -f "${EROOT}"/usr/share/zoneinfo/"${tz}" "${etc_lt}"
 }
 
 pkg_postinst() {