herwig++-2.6.0.ebuild

herwig++-2.6.0.ebuild (text/plain), 1.06 KB, created by Jauhien Piatlicki (RETIRED) on 2012-08-28 13:53:10 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit autotools eutils

MYP=Herwig++-${PV}

DESCRIPTION="High-Energy Physics event generator"
HOMEPAGE="http://herwig.hepforge.org/"
SRC_URI="http://www.hepforge.org/archive/herwig/${MYP}.tar.bz2"

LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~x86"
IUSE="fastjet"

DEPEND="dev-libs/boost
	sci-libs/gsl
	sci-physics/LoopTools
	sci-physics/thepeg
	fastjet? ( sci-physics/fastjet )
"
RDEPEND=""

S="${WORKDIR}/${MYP}"

src_prepare() {
	epatch \
		"${FILESDIR}/${P}-looptools.patch"
	find -name 'Makefile.am' -exec sed -i '1ipkgdatadir=$(datadir)/herwig++' {} \; \
		|| die "changing pkgdatadir name failed"
	eautoreconf
}

src_configure() {
	econf \
		--disable-silent-rules \
		--with-boost="${EPREFIX}"/usr \
		--with-thepeg="${EPREFIX}"/usr \
		$(use_with fastjet fastjet "${EPREFIX}"/usr)
}

src_install () {
	emake DESTDIR="${D}" install
	sed -i "s%${D}%%g" ${D}/usr/share/herwig++/defaults/PDF.in
	sed -i "s%${D}%%g" ${D}/usr/share/herwig++/HerwigDefaults.rpo
}