# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

EAPI=4
JAVA_PKG_IUSE="doc examples source test"

inherit eutils java-pkg-2 java-ant-2

MY_P="${PN}3-${PV}"
DESCRIPTION="Reads XML configuration files to provide initialization of various Java objects within the system."
HOMEPAGE="http://commons.apache.org/digester/"
SRC_URI="mirror://apache/commons/digester/source/${MY_P}-src.tar.gz"

LICENSE="Apache-2.0"
SLOT="3"
KEYWORDS="~amd64"
IUSE=""

RDEPEND=">=virtual/jre-1.5
	dev-java/commons-beanutils:1.7
	dev-java/cglib:2.2
	dev-java/commons-logging:0"
DEPEND=">=virtual/jdk-1.5
	test? (
		dev-java/junit:4
		dev-java/ant-junit
	)
	${RDEPEND}"

S="${WORKDIR}/${MY_P}-src"

JAVA_ANT_REWRITE_CLASSPATH="yes"
EANT_GENTOO_CLASSPATH="commons-beanutils-1.7 cglib-2.2 commons-logging"

java_prepare() {
	cp -v "${FILESDIR}"/${P}_maven-build.xml build.xml || die
}

EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},junit-4"

src_test() {
	#TODO: not all tests are passed; investigate why.
	java-pkg-2_src_test
}

src_install() {
	java-pkg_newjar "target/${MY_P}.jar" ${PN}.jar

	dodoc RELEASE-NOTES.txt || die

	use doc && java-pkg_dojavadoc target/site/apidocs
	use source && java-pkg_dosrc src/main/java/org
	use examples && java-pkg_doexamples src/examples
}