ebuild for media-gfx/opencolorio-1.0.7

opencolorio-1.0.7.ebuild (text/plain), 1.64 KB, created by Sergey Popov on 2012-08-18 09:15:10 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

PYTHON_DEPEND="python? 2"

inherit cmake-utils python

DESCRIPTION="A color management framework for visual effects and animation"
HOMEPAGE="http://opencolorio.org/"
SRC_URI="https://github.com/imageworks/OpenColorIO/tarball/v${PV} \
		-> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="opengl python sse2 test"

DEPEND="opengl? ( media-libs/lcms:2
		media-libs/openimageio
		media-libs/mesa
		media-libs/glew
		media-libs/freeglut
		)"
RDEPEND="${DEPEND}"

# - Documentation building requires Python
# ( removed, see Missing features in src_configure() )
# REQUIRED_USE="doc? ( python )"

GIT_REV="b3cb224"

S="${WORKDIR}/imageworks-OpenColorIO-${GIT_REV}"

src_configure() {
	# Missing features:
	# - Truelight and Nuke are not in portage for now, so their support are disabled
	# - Java bindings was not tested, so disabled
	# - Documentation building uses bundled setuptools which tries to use wrong installation path, need to be patched to avoid this crap
	# Notes:
	# - OpenImageIO is required for building ociodisplay and ocioconvert (USE opengl)
	# - OpenGL, GLUT and GLEW is required for building ociodisplay (USE opengl)
	mycmakeargs=(
		-DOCIO_BUILD_DOCS=OFF
		-DOCIO_BUILD_JNIGLUE=OFF
		-DOCIO_BUILD_NUKE=OFF
		-DOCIO_BUILD_SHARED=ON
		-DOCIO_BUILD_STATIC=OFF
		-DOCIO_STATIC_JNIGLUE=OFF
		-DOCIO_BUILD_TRUELIGHT=OFF
		$(cmake-utils_use opengl OCIO_BUILD_APPS)
		$(cmake-utils_use python OCIO_BUILD_PYGLUE)
		$(cmake-utils_use sse2 OCIO_USE_SSE)
		$(cmake-utils_use test OCIO_BUILD_TESTS)
	)
	cmake-utils_src_configure
}