# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/games-engines/scummvm/scummvm-0.6.0.ebuild,v 1.3 2004/04/12 03:23:19 weeve Exp $

inherit eutils games

DESCRIPTION="Rewrite of the engine used in the game Out of this World"
HOMEPAGE="http://membres.lycos.fr/cyxdown/raw/"
SRC_URI="http://membres.lycos.fr/cyxdown/raw/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE=""

RDEPEND="virtual/glibc
	virtual/x11
	>=media-libs/libsdl-1.2.2
	sys-libs/zlib"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch "${FILESDIR}/txhf-20040426.diff"
	epatch "${FILESDIR}/sound-20040508.diff"
	epatch "${FILESDIR}/makefile.patch"
	sed -i \
		-e 's/$(CXXFLAGS)/$(CXXFLAGS) $(E_CXXFLAGS)/' Makefile \
			|| die "sed Makefile failed"
	edos2unix *cpp *.h
}

src_compile() {
	emake E_CXXFLAGS="${CXXFLAGS}" || die "emake failed"
}

src_install() {
	newgamesbin raw raw-ootw || die "newgamesbin failed"
	dogamesbin ${FILESDIR}/ootw || die "dogamesbin failed"
	sed -i \
		-e "s:GENTOODIR:${GAMES_DATADIR}/${PN}:" "${D}${GAMES_BINDIR}/ootw" \
			|| die "sed failed"
	keepdir "${GAMES_DATADIR}/${PN}"
	dodoc README TODO
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	einfo "Copy the files BANK* and MEMLIST.BIN to ${GAMES_DATADIR}/${PN}"
	einfo "You can then play the game by using the ootw command."
	einfo "Savegames will be stored in ~/.raw"
	einfo "The engine has been installed as raw-ootw.  See the README for"
	einfo "command-line options."
	echo
}