# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/hsqldb/hsqldb-1.8.1.3.ebuild,v 1.3 2012/04/15 18:42:08 vapier Exp $

EAPI=4

JAVA_PKG_IUSE="doc source test"

inherit java-pkg-2 java-ant-2

DESCRIPTION="The leading SQL relational database engine written in Java."
HOMEPAGE="http://hsqldb.org"
SRC_URI="mirror://sourceforge/${PN}/${PN}/${PN}_2_2/${P}.zip"

LICENSE="BSD"
SLOT="2"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~x64-solaris"
IUSE=""

COMMON_DEP="
	java-virtuals/servlet-api:3.0"
RDEPEND="${COMMON_DEP}
	>=virtual/jre-1.6"
DEPEND="${COMMON_DEP}
	>=virtual/jdk-1.6
	app-arch/unzip
	test? ( dev-java/junit:4 )"

S="${WORKDIR}"/${P}/${PN}

java_prepare() {
	find \( -name '*.jar' -o -name '*.zip' \) -exec rm -v {} + || die

	# don't enable java7-only codepaths, currently there aren't any anyway.
	sed -i -e '/available classname="java.sql.PseudoColumnUsage/d' build/build.xml || die

	# doc-src doesn't exist; upstream make dist bug.
	mv doc doc-src || die
}

JAVA_PKG_BSFIX_NAME="build.xml test.xml"
JAVA_ANT_REWRITE_CLASSPATH="yes"
JAVA_ANT_ENCODING="utf8"

EANT_BUILD_XML="build/build.xml"
EANT_BUILD_TARGET="hsqldb hsqldbutil sqltool"
EANT_GENTOO_CLASSPATH="servlet-api-3.0"
EANT_EXTRA_ARGS="-D_servlet_available=true"

EANT_TEST_GENTOO_CLASSPATH="servlet-api-3.0,junit-4" #,ant-core"
EANT_TEST_TARGET="hsqldbtest" #preprocessor"
EANT_TEST_EXTRA_ARGS="-D_junit_available=true" #-Djunit.available=true"

src_test() {
	java-pkg-2_src_test

	# test-src missing from archieve, upstream make dist bug.
	#eant -f build/test.xml make.test.suite run.test.suite

	local classpath=".:lib/hsqldb.jar:lib/hsqldbtest.jar"
	classpath+=":$(java-pkg_getjars --build-only junit-4)" || die
	java -cp ${classpath} org.hsqldb.test.TestUtil || die
}

src_install() {
	java-pkg_dojar lib/{hsqldb,hsqldbutil,sqltool}.jar # TODO others?

	# Servers
	java-pkg_dolauncher ${PN}-server-${SLOT} \
		--main org.hsqldb.server.Server
	java-pkg_dolauncher ${PN}-webserver-${SLOT} \
		--main org.hsqldb.server.WebServer

	# Tools
	java-pkg_dolauncher ${PN}-manager-${SLOT} \
		--main org.hsqldb.util.DatabaseManagerSwing
	java-pkg_dolauncher ${PN}-sqltool-${SLOT} \
		--main org.hsqldb.cmdline.SqlTool
	# TODO others?

	# TODO rc
	#newinitd "${FILESDIR}"/${PN}.init ${PN}
	#newconfd "${FILESDIR}"/${PN}.conf ${PN}

	dodoc doc-src/*.txt
	use && java-pkg_dojavadoc doc/apidocs
	use source && java-pkg_dosrc src/*
}