updated ebuild

qemplayer-12.3.ebuild (text/plain), 1.11 KB, created by wbrana on 2012-06-24 08:36:38 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit flag-o-matic eutils scons-utils

DESCRIPTION="File-manager-like Qt4 GUI front-end to MPlayer"
HOMEPAGE="http://sourceforge.net/projects/qemplayer/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="
	>=x11-libs/qt-sql-4.8:4[sqlite]
	>=x11-libs/qt-gui-4.8:4
	>=dev-libs/libsigc++-2.2.10
	>=dev-db/sqlite-3.7.13[threadsafe]
	|| ( media-video/mplayer media-video/mplayer2 )
	"

DEPEND="${RDEPEND}
	>=sys-devel/gcc-4.4.7
	>=dev-util/scons-2.1.0
	>=dev-util/pkgconfig-0.26
	"

pkg_setup() {
	local major=$(gcc-major-version)
	local minor=$(gcc-minor-version)
	if (( major < 4 || ( major == 4 && minor < 4 ) )); then
		die "gcc 4.4.7 or newer is required"
	fi
}

src_compile() {
	local opts
	use debug && opts="${opts} debug=1"
	escons -j1 final=1 env=1 ${opts}
}

src_install() {
	local opts
	use debug && opts="${opts} debug=1"
	dodir /usr
	escons -j1 install prefix="${D}"usr final=1 env=1 ${opts}
	dodoc INSTALL README CHANGES
}