ebuild for qgis-1.8

qgis-1.8.0.ebuild (text/plain), 2.80 KB, created by yarma on 2012-06-22 13:42:10 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/qgis/qgis-1.7.3.ebuild,v 1.2 2012/02/05 01:56:14 floppym Exp $

EAPI=3

PYTHON_USE_WITH="sqlite"
PYTHON_DEPEND="python? 2"
inherit python base cmake-utils eutils multilib

DESCRIPTION="User friendly Geographic Information System"
HOMEPAGE="http://www.qgis.org/"
SRC_URI="http://qgis.org/downloads/${P}.tar.bz2
	examples? ( http://download.osgeo.org/qgis/data/qgis_sample_data.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples georeferencer gps grass postgres python mapserver test"

RDEPEND="
	>=dev-db/sqlite-3.0.0
	>=sci-libs/gdal-1.4
	>=sci-libs/geos-3.0
	sci-libs/libspatialindex
	>=sci-libs/proj-4.4
	>=x11-libs/qt-core-4.4.0
	>=x11-libs/qt-gui-4.4.0
	>=x11-libs/qt-sql-4.4.0
	>=x11-libs/qt-svg-4.4.0
	>=x11-libs/qt-webkit-4.4.0
	>=x11-libs/qwt-5.0
	gps? (
		>=dev-libs/expat-1.95
		sci-geosciences/gpsbabel
		)
	mapserver? (
		dev-libs/fcgi
		)
	postgres? ( >=dev-db/postgresql-base-8.0 )
	python? (
		>=dev-lang/python-2.3
		>=dev-python/PyQt4-4.4.0[X,sql,svg]
		>=dev-python/sip-4.8
		)
	grass? ( >=sci-geosciences/grass-6.0.0[python?] )
	georeferencer? ( >=sci-libs/gsl-1.8 )"

DEPEND="${RDEPEND}
	>=dev-util/cmake-2.6.2
	>=sys-devel/bison-2.4
	sys-devel/flex"

DOCS=( BUGS NEWS README )

# Does not find the test binaries at all
RESTRICT="test"

pkg_setup() {
	if use python ; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_configure() {
	local mycmakeargs+=(
		"-DQGIS_MANUAL_SUBDIR=/share/man/"
		"-DBUILD_SHARED_LIBS=ON"
		"-DBINDINGS_GLOBAL_INSTALL=ON"
		"-DQGIS_LIB_SUBDIR=$(get_libdir)"
		"-DQGIS_PLUGIN_SUBDIR=$(get_libdir)/qgis"
		"-DWITH_INTERNAL_SPATIALITE=OFF"
		"-DWITH_INTERNAL_QWTPOLAR=OFF"
		"-DPEDANTIC=OFF"
		"-DWITH_APIDOC=OFF"
		$(cmake-utils_use_with postgres POSTGRESQL)
		$(cmake-utils_use_with grass GRASS)
		$(cmake-utils_use_with mapserver MAPSERVER)
		$(cmake-utils_use_with python BINDINGS)
		$(cmake-utils_use python BINDINGS_GLOBAL_INSTALL)
		$(cmake-utils_use_with spatialite SPATIALITE)
		$(cmake-utils_use_enable test TESTS)
	)
	use grass && mycmakeargs+=( "-DGRASS_PREFIX=/usr/" )

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newicon images/icons/qgis-icon.png qgis.png || die
	make_desktop_entry qgis "Quantum GIS" qgis

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r "${WORKDIR}"/qgis_sample_data/* || die "Unable to install examples"
	fi
}

pkg_postinst() {
	if use postgres; then
		elog "If you don't intend to use an external PostGIS server"
		elog "you should install:"
		elog "   dev-db/postgis"
	fi
	use python && python_mod_optimize qgis /usr/share/qgis/python/plugins
}

pkg_postrm() {
	use python && python_mod_cleanup qgis /usr/share/qgis/python/plugins
}