# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
inherit cmake-utils games

DESCRIPTION="An open source reimplementation of the role playing game The Elder Scrolls III: Morrowind"
HOMEPAGE="http://openmw.org/"
SRC_URI="https://openmw.googlecode.com/files/openmw-${PV}-source.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ffmpeg +mpg123"

S="${WORKDIR}/zinnschlag-${PN}-94498f5"


RDEPEND="=dev-games/ogre-1.8*[boost,cg,freeimage,ois,opengl,threads,zip]
	dev-games/mygui[ogre]
	sci-physics/bullet
	dev-games/ois
	media-gfx/nvidia-cg-toolkit
	>=x11-libs/qt-gui-4.7.0:4
	media-libs/openal
	media-libs/freetype:2
	dev-libs/zziplib
	ffmpeg? ( media-video/ffmpeg )
	mpg123? ( media-libs/libsndfile
		media-sound/mpg123 )"

PDEPEND="games-rpg/morrowind-data"

DEPEND="${RDEPEND}
	>=dev-libs/boost-1.45.0
	dev-util/pkgconfig"

src_prepare() {
    epatch "${FILESDIR}"/${P}-cmake.patch

    sed \
	-e "s#globalPath(\"/etc/\")#globalPath(\"${GAMES_SYSCONFDIR}\")#" \
	-i components/files/linuxpath.cpp || die
}

src_configure() {
    local mycmakeargs=(
	    -DBINDIR="${GAMES_BINDIR}"
	    -DDATADIR="${GAMES_DATADIR}"/${PN}
	    -DSYSCONFDIR="${GAMES_SYSCONFDIR}"/${PN}
	    $(cmake-utils_use ffmpeg USE_FFMPEG)
	    $(cmake-utils_use mpg123 USE_MPG123)
	)

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_make
}

src_install() {
	sed -i \
	-e 's:data="?mw?Data Files":data=/opt/morrowind:' \
	${CMAKE_BUILD_DIR}/openmw.cfg.install
	
	cmake-utils_src_install
	dodoc "${S}"/readme.txt
	
	prepgamesdirs
}