# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

EAPI=2
inherit eutils games

DESCRIPTION="point-and-click puzzle adventure game"
HOMEPAGE="http://machinarium.net/"
SRC_URI="${PN^}_full_en.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="amd64 ~x86"
IUSE=""
RESTRICT="fetch strip"

RDEPEND="virtual/opengl
	amd64? ( app-emulation/emul-linux-x86-gtklibs
		app-emulation/emul-linux-x86-opengl )
	x86? ( app-arch/bzip2
		dev-libs/expat
		dev-libs/nss
		media-libs/fontconfig
		=media-libs/libpng-1.5*
		sys-apps/util-linux
		sys-libs/zlib
		x11-libs/cairo
		x11-libs/gtk+
		x11-libs/libXcomposite
		x11-libs/libXcursor
		x11-libs/libXdamage
		x11-libs/libXdmcp
		x11-libs/libXi
		x11-libs/libXinerama
		x11-libs/libXrandr
		x11-libs/libXt
		x11-libs/libxcb )"
DEPEND=""

S=${WORKDIR}/${PN^}

GAMEDIR=${GAMES_PREFIX_OPT}/${PN}

pkg_nofetch() {
	elog "Please purchase and download '${SRC_URI}'"
	elog "then copy to: '${DISTDIR}'"
	echo
}

src_install() {
	insinto "${GAMEDIR}"
	exeinto "${GAMEDIR}"

	# Install game files
	doins -r 00 01 10 11 || die "install data failed"
	doexe ${PN^} || die "install bin failed"

	# install shortcuts
	games_make_wrapper ${PN} ./${PN^} "${GAMEDIR}" \
		|| die "install wrapper failed"
	make_desktop_entry ${PN} ${PN^} \
		|| die "install shortcut failed"
	prepgamesdirs
}

pkg_postinst() {
	einfo "To play the game, run:"
	einfo "${PN}"
	echo
	einfo "This games run inside an self-contained Flash player.  If you get just a"
	einfo "blank (black) screen when launching the game, try setting the following in"
	einfo "/etc/adobe/mms.cfg:"
	einfo
	einfo "LocalFileReadDisable = 0"
	einfo
	einfo "Also, in the Flash settings applet, try disabling hardware acceleration."
	echo
	games_pkg_postinst
}