games-arcade/jaspers-journeys-2.15.ebuild

jaspers-journeys-2.15.ebuild (text/plain), 1.26 KB, created by Jared B. on 2012-06-11 03:56:46 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:  $

EAPI=2
inherit eutils games

DESCRIPTION="old school sprite-based platformer"
HOMEPAGE="http://www.lexaloffle.com/jasper.php"
SRC_URI="${PN}_${PV}_i386.tar.gz"

LICENSE="Lexaloffle"
SLOT="0"
KEYWORDS="amd64 ~x86"
IUSE=""
RESTRICT="fetch"

RDEPEND="
	amd64? ( app-emulation/emul-linux-x86-sdl
		app-emulation/emul-linux-x86-soundlibs )
	x86? ( media-libs/libsdl
		media-libs/alsa-lib )"
DEPEND=""

S=${WORKDIR}/${PN}

GAMEDIR=${GAMES_PREFIX_OPT}/${PN}

pkg_nofetch() {
	elog "Please purchase and download '${SRC_URI}'"
	elog "then copy to: '${DISTDIR}'"
	echo
}

src_install() {
	insinto "${GAMEDIR}"
	exeinto "${GAMEDIR}"

	# Install game files
	doins jasper.dat || die "install dat failed"
	doexe jasper || die "install bin failed"

	# install documentation
	dodoc ${PN}.txt || die "install doc failed"

	# install shortcuts
	newicon lexaloffle-jasper.png ${PN}.png || die "install icon failed"
	games_make_wrapper ${PN} ./jasper "${GAMEDIR}" \
		|| die "install wrapper failed"
	make_desktop_entry ${PN} "Jasper's Journeys" \
		|| die "install shortcut failed"
	prepgamesdirs
}

pkg_postinst() {
	einfo "To play the game, run:"
	einfo "${PN}"
	echo
	games_pkg_postinst
}