# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils games

DESCRIPTION="Play as an amorphous ball of tar that rolls and squishes around"
HOMEPAGE="http://www.chroniclogic.com/gish.htm"
SRC_URI="${PN}_${PV}_all.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="-* amd64 x86"
IUSE="doc"
RESTRICT="strip fetch"
QA_EXECSTACK="${GAMES_PREFIX_OPT:1}/${PN}/gish"

RDEPEND="media-libs/libsdl
	media-libs/sdl-image
	media-libs/libvorbis
	media-libs/openal
	virtual/opengl"

S="${WORKDIR}/${PN}"

pkg_nofetch() {
	einfo "This game must be purchased from ${HOMEPAGE}."
	einfo "You will receive instructions on how to download ${SRC_URI}. Place"
	einfo "this file in ${DISTDIR} once you have it and then restart"
	einfo "this merge."
}

src_install() {
	local dir=${GAMES_PREFIX_OPT}/${PN}

	insinto "${dir}"
	doins -r animation data level music player replay sound texture tile?? \
		|| die "doins failed"

	exeinto "${dir}"
	use amd64 && BIN="${PN}_64" || BIN="${PN}_32"
	newexe ${BIN} ${PN} || die "newexe failed"
	games_make_wrapper ${PN} ./${PN} "${dir}" || die "make wrapper failed"

	# Using an absolute path is ugly, but required for BMP icons
	doicon ${PN}.bmp || die "doicon failed"
	make_desktop_entry ${PN} "Gish" "/usr/share/pixmaps/${PN}.bmp" \
		|| die "make desktop failed"

	dodoc {README,gisheditor}.txt Patch_*.txt || die "dodoc failed"
	if use doc; then
		dohtml -A swf *.html *.swf || die "dohtml failed"
	fi

	prepgamesdirs
}

pkg_postinst() {
	# Is this still a problem?
	ewarn "This game is known to crash shortly after starting level 1-6. You can"
	ewarn "work around this by turning off the music just for that level. This has"
	ewarn "been reported upstream."
	echo
	games_pkg_postinst
}