form-4.0_p20120529.ebuild

form-4.o_p20120529.ebuild (text/plain), 1.38 KB, created by Jauhien Piatlicki (RETIRED) on 2012-05-31 10:43:22 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit autotools

DESCRIPTION="Symbolic Manipulation System"
HOMEPAGE="http://www.nikhef.nl/~form/"
SRC_URI="http://github.com/downloads/jauhien/sources/${P}.tar.gz"

S="${WORKDIR}/formcvs"

LICENSE="GPL-3"

SLOT="0"
KEYWORDS="~x86"
IUSE="devref doc doxygen gmp mpi +scalar threaded zlib"

DEPEND="devref? ( dev-texlive/texlive-latex )
	doc? ( dev-texlive/texlive-latex )
	doxygen? ( app-doc/doxygen )
	gmp? ( dev-libs/gmp )
	mpi? ( virtual/mpi )
	zlib? ( sys-libs/zlib )
"
RDEPEND="${DEPEND}"

src_prepare() {
	sed -i 's/LINKFLAGS = -s/LINKFLAGS =/' sources/Makefile.am || die
	eautoreconf
}

src_configure() {
	econf \
		--enable-largefile \
		--disable-debug \
		--disable-static-link \
		--with-api=posix \
		$(use_with gmp ) \
		$(use_enable mpi parform ) \
		$(use_enable scalar ) \
		$(use_enable threaded ) \
		$(use_with zlib ) \
		CC="$(tc-getCC)" \
		CXX="$(tc-getCXX)" \
		CFLAGS="${CFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		CXXFLAGS="${CXXFLAGS}"
}

src_install() {
	emake DESTDIR="${D}" install
	if use devref; then
		pushd doc/devref || die
		LANG=C emake pdf
		dodoc devref.pdf
		popd
	fi
	if use doc; then
		pushd doc/manual || die
		LANG=C emake pdf
		dodoc manual.pdf
		popd
	fi
	if use doxygen; then
		pushd doc/doxygen || die
		emake html
		dohtml -r html/*
		popd
	fi
}