kawoken-1.2.ebuild

file_415711.txt (text/plain), 1.34 KB, created by Shubhadeep Chaudhuri on 2012-05-13 08:33:30 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

MY_PN="kAwOken"
DESCRIPTION="KDE port of the AwOken icon theme"
HOMEPAGE="http://alecive.deviantart.com/art/kAwOken-244166779"
SRC_URI="http://www.deviantart.com/download/244166779/kawoken_by_alecive-d41dcaj.zip -> ${P}.zip"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

RESTRICT="binchecks strip"
S="${WORKDIR}/${MY_PN}-${PV}"

src_unpack() {
	unpack "${A}"
	cd ${MY_PN}-${PV}
	unpack "./${MY_PN}.tar.gz" "./${MY_PN}Dark.tar.gz" "./${MY_PN}White.tar.gz"
}

src_prepare() {
	local res
	for theme in ${MY_PN}{,Dark,White}; do
		for res in 22 128; do
			ln -sf ../start-here/start-here-gentoo2.png \
				${S}/${theme}/clear/${res}x${res}/places/start-here.png || die
		done
	done
	sed -i -e "s:\$DIR/\$ICNST/Installation_and_Instructions.pdf:/usr/share/doc/${P}/Installation_and_Instructions.pdf:"  ${MY_PN}/kawoken-icon-theme-customization
}

src_install() {
	for theme in ${MY_PN}{,Dark,White}; do
		insinto /usr/share/icons/${theme}
		doins -r ${theme}/{clear,extra} || die
		doins -r ${theme}/index.theme
		doins -r ${theme}/kawoken-icon-theme-customization-* || die
	done
	dobin ${MY_PN}/kawoken-icon-theme-customization{,-clear}
	dodoc ${MY_PN}/Installation_and_Instructions.pdf
}