blueglass-xcursors-0.4-r1.ebuild

blueglass-xcursors-0.4-r1.ebuild (text/plain), 2.04 KB, created by Diego Elio Pettenò (RETIRED) on 2004-05-07 23:00:08 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/x11-themes/blueglass-xcursors/blueglass-xcursors-0.4.ebuild,v 1.7 2004/04/27 19:52:28 pvdabeel Exp $

MY_P="5532-BlueGlass-XCursors-3D-${PV}"
DESCRIPTION="A high quality set of X11 animated mouse cursors"
HOMEPAGE="http://www.kde-look.org/content/show.php?content=5532"
SRC_URI="http://www.kde-look.org/content/files/${MY_P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="x86 sparc amd64 ~alpha ppc"

IUSE=""
DEPEND=""
RDEPEND="virtual/x11"

S=${WORKDIR}

pkg_setup() {
	if has_version "x11-base/xfree"
	then
		if ! has_version ">=x11-base/xfree-4.3.0-r2"
		then
			die "You must upgrade to xfree-4.3.0-r2 or greater to use this."
		fi
	fi

	# Set up X11 implementation
	X11_IMPLEM_P="$(best_version virtual/x11)"
	X11_IMPLEM="${X11_IMPLEM_P%-[0-9]*}"
	X11_IMPLEM="${X11_IMPLEM##*\/}"
	einfo "X11 implementation is ${X11_IMPLEM}."
}

# Note: although the package name is BlueGlass, the tarball & authors directions
# use the directory 'Blue'.
src_install() {
	insinto "/usr/share/cursors/${X11_IMPLEM}/Blue/cursors"
	doins ${MY_P:5}/Blue/cursors/*
	insinto "/usr/share/cursors/${X11_IMPLEM}/Blue"
	doins ${MY_P:5}/Blue/index.theme

	dodoc ${MY_P:5}/{COPYING,README}
}

pkg_postinst() {
	einfo "To use this set of cursors, edit or create the file ~/.Xdefaults"
	einfo "and add the following line:"
	einfo "Xcursor.theme: Blue"
	einfo ""
	einfo "Also, you can change the size by adding a line like:"
	einfo "Xcursor.size: 48"
	einfo ""
	einfo "To globally use this set of mouse cursors edit the file:"
	einfo "   /usr/share/cursors/${X11_IMPLEM}/default/index.theme"
	einfo "and change the line:"
	einfo "    Inherits=[current setting]"
	einfo "to"
	einfo "    Inherits=Blue"
	einfo ""
	einfo "Note this will be overruled by a user's ~/.Xdefaults file."
	einfo ""
	ewarn "If you experience flickering, try setting the following line in"
	ewarn "the Device section of your XF86Config (or xorg.conf):"
	ewarn "Option  \"HWCursor\"  \"false\""
}