# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3
inherit eutils

DESCRIPTION="Backup client/server for Unix and Windows systems."
HOMEPAGE="http://burp.grke.net/"
SRC_URI="http://download.sourceforge.net/${PN}/${P}.tar.bz2"

LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="static"

DEPEND=">=net-libs/librsync-0.9
	>=dev-libs/openssl-0.9
	>=dev-libs/uthash-1.9
	>=sys-apps/attr-2.4
	>=sys-libs/zlib-1.2.5
	>=sys-libs/ncurses-5
	>=sys-apps/acl-2.2
	static? ( sys-libs/zlib[static-libs] \
              net-libs/librsync[static-libs] \
              dev-libs/openssl[static-libs] \
              sys-apps/attr[static-libs] \
              net-libs/librsync[static-libs] \
              sys-libs/ncurses[static-libs] \
              sys-apps/acl[static-libs] )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/burp"

pkg_preinst() {
	enewgroup burp || die
	enewuser burp -1 -1 -1 burp || die
}

src_configure() {
    #  --disable-libtool \
	econf --sysconfdir=/etc/burp \
        $(use_enable static) 
}

src_install() {
	dosbin src/burp src/bedup configs/certs/CA/burp_ca
	use static && dosbin src/static-burp src/static-bedup

	doman manpages/burp.8 manpages/bedup.8 manpages/burp_ca.8

	dodoc docs/*
	dodoc UPGRADING CONTRIBUTORS DONATIONS TODO README CHANGELOG

	# These directories must be writable by the server process
	# which is run as burp:burp
	dodir /var/lib/burp /var/run/burp /var/log/burp
	fowners root:burp /var/lib/burp /var/run/burp /var/log/burp
	fperms 775 /var/lib/burp /var/run/burp /var/log/burp

	# Server configuration
	insinto /etc/burp
	newins configs/server/burp.conf burp-server.conf
	doins configs/server/notify_script
	doins configs/server/ssl_extra_checks_script
	doins configs/server/summary_script
	doins configs/server/timer_script
	doins configs/certs/CA/CA.cnf
	insinto /etc/burp/autoupgrade/server/win32
	newins configs/server/autoupgrade/windows.script script
	dodir /etc/burp/autoupgrade/server/win32/${PV}
	insinto /etc/burp/autoupgrade/server/win64
	newins configs/server/autoupgrade/windows.script script
	dodir /etc/burp/autoupgrade/server/win64/${PV}
    newinitd "${FILESDIR}/${PN}.initd" ${PN}
    sed -i -e 's:^# user=graham:user = burp:;s:^# group=nogroup:group = burp:' "${D}"/etc/burp/burp-server.conf || die
    sed -i -e 's:^pidfile = /var/run/burp.server.pid:lockfile = /var/run/burp/burp-server.lck:' "${D}"/etc/burp/burp-server.conf || die
    sed -i -e 's:^directory = /var/spool/burp:directory = /var/lib/burp:' "${D}"/etc/burp/burp-server.conf || die
	echo "logfile = /var/log/burp/burp-server.log" >> "${D}"/etc/burp/burp-server.conf || die

	# The config directory must be writable by the server process
	fowners root:burp /etc/burp
	fperms 775 /etc/burp

	# Client configuration
	insinto /etc/burp
	doins configs/client/burp.conf

	dodir /etc/burp/autoupgrade/client

	insinto /etc/burp/clientconfdir
	doins configs/server/clientconfdir/testclient

	insinto /etc/burp/clientconfdir/incexc
	newins configs/server/clientconfdir/incexc example

	# The server will create this directory if it doesn't exist, but the client
	# won't. It must be writable by both.
	dodir /etc/burp/CA
	fowners root:burp /etc/burp/CA
	fperms 775 /etc/burp/CA

}

pkg_postinst() {
	einfo "Generating initial CA certificates and keys if necessary..."
	# Set $HOME to a directory writable by the server process
	# OpenSSL writes its "random state" file there while generating the certs/keys
	HOME=/var/lib/burp burp -F -c /etc/burp/burp-server.conf -g
}