logjam-4.6.2.ebuild

logjam-4.6.2.ebuild (text/plain), 987 bytes, created by James Le Cuirot on 2012-04-13 20:44:33 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

DESCRIPTION="GTK2-based LiveJournal client"
HOMEPAGE="http://logjam.danga.com/"
SRC_URI="http://andy-shev.github.com/LogJam/download/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+gtk gtkhtml soup spell sqlite svg"

RDEPEND="dev-libs/dbus-glib
	dev-libs/libxml2
	gtk? ( x11-libs/gtk+:2 )
	gtkhtml? ( gnome-extra/gtkhtml:3.14 )
	soup? ( net-libs/libsoup:2.4 )
	!soup? ( net-misc/curl )
	spell? ( app-text/gtkspell:2 )
	sqlite? ( dev-db/sqlite:3 )
	svg? ( gnome-base/librsvg )"

DEPEND="${RDEPEND}
	dev-util/intltool
	dev-util/pkgconfig"

DOCS="ChangeLog doc/README doc/TODO"

src_configure() {
	econf \
		$(use_with gtk) \
		$(use_with gtkhtml gtkhtml314) \
		$(use_with soup libsoup) \
		$(use_with spell gtkspell) \
		$(use_with sqlite sqlite3) \
		$(use_with svg librsvg) \
		--with-dock \
		--without-banshee \
		--without-xmms
}