# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit eutils

DESCRIPTION="An authoritative only, high performance, open source name server"
HOMEPAGE="http://www.nlnetlabs.nl/projects/nsd"
SRC_URI="http://www.nlnetlabs.nl/downloads/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bind8-stats ipv6 largefile +nsec3 root-server runtime-checks mmap dnssec-tools"

DEPEND="dev-libs/openssl"
RDEPEND="nsec3? ( dnssec-tools? ( net-dns/ldns-utils[examples] ) )
	${DEPEND}"

pkg_setup() {
	if use runtime-checks; then
		ewarn "You enabled runtime-checks USE flag, this could lead to a reduced service level."
	fi
	enewgroup nsd
	enewuser nsd -1 -1 -1 nsd
}

src_configure() {
	econf \
		$(use_enable bind8-stats) \
		$(use_enable largefile) \
		$(use_enable ipv6) \
		$(use_enable nsec3) \
		$(use_enable root-server) \
		$(use_enable mmap) \
		$(use_enable runtime-checks checking)
		--with-dbfile=/var/db/nsd/nsd.db \
		--with-difffile=/var/db/nsd/ixfr.db \
		--with-pidfile=/var/run/nsd/nsd.pid \
		--with-xfrdfile=/var/db/nsd/xfrd.state \
		--with-zonesdir=/var/lib/nsd
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc doc/{ChangeLog,CREDITS,NSD-FOR-BIND-USERS,README,REQUIREMENTS}

	insinto /usr/share/${PN}
	doins contrib/nsd.zones2nsd.conf

	exeinto /etc/cron.daily
	doexe "${FILESDIR}"/nsd.cron

	newinitd "${FILESDIR}"/nsd.initd nsd
	newconfd "${FILESDIR}"/nsd.confd nsd

	# database directory, writable by nsd for ixfr.db file
	dodir /var/db/nsd
	fowners nsd:nsd /var/db/nsd
	fperms 750 /var/db/nsd

	# zones directory, writable by root for 'nsdc patch'
	dodir /var/lib/nsd
	fowners root:nsd /var/lib/nsd
	fperms 750 /var/lib/nsd

	# pid dir, writable by nsd
	dodir /var/run/nsd
	fowners nsd:nsd /var/run/nsd
}

pkg_postinst() {
	elog "If you are using bind and want to convert (or sync) bind zones,"
	elog "you should check out bind2nsd (http://bind2nsd.sourceforge.net)."
}