netzob git@master ebuild

netzob-9999.ebuild (text/plain), 1.24 KB, created by Alexandre PIGNÉ on 2012-03-13 10:51:51 UTC

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
PYTHON_DEPEND="2:2.6"
SUPPORT_PYTHON_ABIS="1"

inherit distutils git-2

MY_P="Netzob-${PV}"

DESCRIPTION="Network protocol modelization by reverse engineering"
HOMEPAGE="http://www.netzob.org/"
EGIT_REPO_URI="https://dev.netzob.org/git/netzob.git"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS=""
IUSE="doc"

RDEPEND="
	dev-python/pcapy
	dev-python/impacket
	dev-python/pygtk
	>=dev-python/python-ptrace-0.4.1
	dev-python/matplotlib
	dev-util/strace
	sys-process/lsof
	>=dev-python/lxml-2.3
	dev-python/bitarray
"
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx )"

RESTRICT_PYTHON_ABIS="3.*"

S="${WORKDIR}/${MY_P}"
DOCS="README.txt AUTHORS.txt NEWS.txt COPYING.txt"

src_prepare() {
	distutils_src_prepare
	sed -i "s;resources/static;/usr/share/netzob;" src/netzob/NetzobResources.py || die
}

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		pushd doc/documentation >/dev/null
		sphinx-build -b html source html || die "Generation of documentation failed"
		popd >/dev/null
	fi
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml -r doc/documentation/html/* || die "dohtml failed"
	fi
}