# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/duke3d-data/duke3d-data-1.0.ebuild,v 1.5 2010/04/26 11:55:23 fauli Exp $

EAPI=2

inherit eutils games

DESCRIPTION="Duke Nukem 3D data files"
HOMEPAGE="http://www.3drealms.com/"
SRC_URI=""

LICENSE="DUKE3D"
SLOT="0"
KEYWORDS="amd64 hppa ppc x86"
PROPERTIES="interactive"
IUSE=""

DEPEND=""
RDEPEND=""

src_unpack() {
	export DATAROOT
	export CDROM_NAME_SET=("Existing Install" "Duke Nukem 3D CD" "Duke Nukem 3D Atomic Edition CD")
	cdrom_get_cds duke3d.grp:dn3dinst/duke3d.grp:atominst/duke3d.grp

	case ${CDROM_SET} in
		0)
			DATAROOT="."
			einfo "Found ${CDROM_NAME_SET[0]}" ;;
		1)
			DATAROOT="dn3dinst"
			einfo "Found ${CDROM_NAME_SET[1]}" ;;
		2)
			DATAROOT="atominst"
			einfo "Found ${CDROM_NAME_SET[2]}" ;;
		*) die "Duke Nukem 3D files not found" ;;
	esac
}

src_install() {
	insinto "${GAMES_DATADIR}/duke3d"

	doins "${CDROM_ROOT}/${DATAROOT}"/{duke3d.grp,duke.rts,demo?.dmo} \
		|| die "doins failed"
	dodoc "${CDROM_ROOT}/${DATAROOT}"/*.doc || die "dodoc failed"

	prepgamesdirs
}


pkg_postinst() {
	if ! has_version games-fps/duke3d && ! has_version games-fps/eduke32; then
		echo
		einfo "Note:  You must also install a game engine, such as games-fps/duke3d or"
		einfo "(preferably) games-fps/eduke32, in order to play Duke Nukem 3D."
		echo
	fi
}