spotify-0.6.2.291.ebuild

spotify-0.6.2.291.ebuild (text/plain), 2.40 KB, created by Ortwin Glueck on 2012-02-28 08:55:14 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

DESCRIPTION="Spotify is a social music platform"
HOMEPAGE="https://www.spotify.com/ch-de/download/previews/"
SRC_URI="amd64? ( http://repository.spotify.com/pool/non-free/s/spotify/spotify-client-qt_${PV}.gcccc1f5.116-1_amd64.deb )
         x86? ( http://repository.spotify.com/pool/non-free/s/spotify/spotify-client-qt_${PV}.gcccc1f5.116-1_i386.deb )"
LICENSE="Spotify"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="pulseaudio"

DEPEND=""
RDEPEND="${DEPEND}
		x11-libs/libX11
		x11-libs/libSM
		x11-libs/libICE
		x11-libs/libXrender
		x11-libs/libXrandr
		x11-libs/libXinerama
		x11-libs/libXext
		x11-libs/libxcb
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/qt-core:4
		x11-libs/qt-gui:4
		x11-libs/qt-webkit:4
		x11-libs/qt-dbus:4
		x11-libs/libXScrnSaver
		media-libs/freetype
		media-libs/fontconfig
		media-libs/alsa-lib
		media-libs/phonon
		dev-libs/openssl
		dev-libs/glib:2
		>media-libs/libpng-1.5
		dev-db/sqlite:3
		sys-libs/zlib
		app-arch/bzip2
		sys-apps/dbus
		sys-apps/util-linux
		dev-libs/expat
		pulseaudio? ( >=media-sound/pulseaudio-0.9.21 )"

RESTRICT="mirror strip"

src_unpack() {
	mkdir "${P}"
	cd "${P}"
	unpack "${A}" 
	unpack ./data.tar.gz
	# link against openssl-1.0.0 as it crashes with 0.9.8
	sed -i -e 's/\(lib\(ssl\|crypto\).so\).0.9.8/\1.1.0.0/g' usr/bin/spotify
}

src_install() {
	dodoc usr/share/doc/spotify-client-qt/changelog.Debian.gz
	dodoc usr/share/doc/spotify-client-qt/copyright
	insinto /usr/share/applications
	doins usr/share/applications/*.desktop
	insinto /usr/share/pixmaps
	doins usr/share/pixmaps/*.png
	dodir /usr/share/spotify
	insinto /usr/share/spotify
	doins -r usr/share/spotify/*

	# install the binary in /opt/spotify
	declare SPOTIFY_HOME=/opt/spotify
	dodir ${SPOTIFY_HOME}
	insinto ${SPOTIFY_HOME}
	doins usr/bin/spotify

	# Create /usr/bin/spotify wrapper
	dodir /usr/bin/
	cat <<-EOF >"${D}"/usr/bin/${PN}
	#!/bin/sh
	exec $SPOTIFY_HOME/spotify "\$@"
	EOF
	fperms 0755 /usr/bin/${PN}
	fperms 0755 $SPOTIFY_HOME/${PN}

	# revdep-rebuild produces a false positive because of symbol versioning
	dodir /etc/revdep-rebuild
	cat <<-EOF >"${D}"/etc/revdep-rebuild/10"${PN}"
	SEARCH_DIRS_MASK="$SPOTIFY_HOME"
	EOF
}

pkg_postinst() {
	einfo "If Spotify crashes after an upgrade its cache may be corrupt."
	einfo "To remove the cache:"
	einfo "rm -rf ~/.cache/spotify"
}