# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4
inherit eutils fdo-mime

MY_PN=processing
MY_P=${MY_PN}-${PV}

DESCRIPTION="Open source programming language and environment to create gui"
HOMEPAGE="http://processing.org/"
# no source-code available
SRC_URI="http://${MY_PN}.googlecode.com/files/${MY_P}-linux.tgz 
         http://wiki.processing.org/skins/processingskin/processing_wiki_logo.png"

LICENSE="GPL-2 LGPL-2"		
SLOT="0"
KEYWORDS="~amd64 ~x86"
RESTRICT="strip"
IUSE=""
RDEPEND="
	dev-java/ant-core
	dev-java/antlr
	dev-java/eclipse-ecj:3.7
	dev-java/jna
	>=virtual/jdk-1.6"

S=${WORKDIR}/${MY_P}

src_prepare() {
	# fix check of system java, fix CLASSPATH
	epatch "${FILESDIR}"/wrapper-${PV}.patch
}

src_install() {
	# we use system java
	rm -r java || die "Removing of packaged java failed"

	# get rid of libraries provided by other packages
	rm lib/{ant.jar,ant-launcher.jar,antlr.jar,ecj.jar,jna.jar} \
		|| die "Removing of libs failed"

	# install
	dodir "/usr/share/${P}/"
	cp -a "${S}"/* "${D}/usr/share/${P}" || die "Copying failed"
	dosym /usr/share/${P}/${MY_PN} /usr/bin/${MY_PN}
	domenu "${FILESDIR}"/${PN}.desktop
	newicon "${DISTDIR}"/processing_wiki_logo.png ${MY_PN}.png 
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}