# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

WANT_ANT_TASKS="ant-nodeps"
JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2

DESCRIPTION="A XSLT and XQuery Processor"
HOMEPAGE="http://saxon.sourceforge.net/"
# svn export http://www.saxonica.co.uk/repos/archive/opensource/tags/${PV}
# mv ${PV} ${P}
# tar cjf ${P}.tar.bz2 --owner 0 --group 0 --numeric-owner ${P}
SRC_URI="${P}.tar.bz2"

LICENSE="MPL-1.1"
SLOT="saxon-b"
KEYWORDS="~x86"

IUSE=""

COMMON_DEP="dev-java/xom:0
	dev-java/dom4j:1
	dev-java/ant-core:0
	dev-java/jdom:1.0"

RDEPEND=">=virtual/jre-1.5
	${COMMON_DEP}"
DEPEND=">=virtual/jdk-1.5
	${COMMON_DEP}"

java_prepare() {
	find -name "*.class" -exec rm -v {} +
	epatch "${FILESDIR}/delSAbuild.patch"
	# remove ants get tasks
	find -name build.xml \
		-exec sed -e 's/<get [^>]*\/>//g' \
				  -e '/<get[^>]*[^\/]>/,/<\/get>/d' \
				  -e '/<get[^>]*/,/[^>]\/>/d' \
				  -e '/<unzip[^>]*[^\/]>/,/<\/unzip>/d' \
				  -e '/<unjar[^>]*[^\/]>/,/<\/unjar>/d' -i {} \;
	mkdir libs temp services
	java-pkg_jar-from --into libs xom
	java-pkg_jar-from --into libs dom4j-1
	java-pkg_jar-from --into libs jdom-1.0
	java-pkg_jar-from --into libs ant-core
}

src_compile() {
	eant create-meta-inf bj $(use_doc product-javadoc) \
			-f build/build.xml \
			-Ddevelopment-j.dir="${S}" \
			-Dsource-bj.dir="${S}"/bj \
			-Dlib.dir="${S}"/libs \
			-Dservices.dir="${S}"/services \
			-Dtemp.dir="${S}"/temp \
			-Doroot="${S}" \
			-Dversion="${PV}"
}

src_install() {
	java-pkg_dojar saxon-build/${PV}/bj/saxon9*.jar
	java-pkg_dolauncher ${PN}9b --jar saxon9.jar
	use doc && java-pkg_dojavadoc saxon-build/${PV}/resources/doc/javadoc
	use source && java-pkg_dosrc bj/*
}