the ebuild

openocd-9999.ebuild (text/plain), 2.95 KB, created by Edwin Peer on 2012-02-15 08:39:58 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/openocd/openocd-9999.ebuild,v 1.20 2011/11/15 21:12:38 vapier Exp $

EAPI="4"

inherit eutils
if [[ ${PV} == "9999" ]] ; then
	inherit autotools git-2
	KEYWORDS=""
	EGIT_REPO_URI="git://${PN}.git.sourceforge.net/gitroot/${PN}/${PN}"
else
	KEYWORDS="~amd64 ~x86"
	SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${PV}/${P}.tar.bz2"
fi

DESCRIPTION="OpenOCD - Open On-Chip Debugger"
HOMEPAGE="http://openocd.sourceforge.net"

LICENSE="GPL-2"
SLOT="0"
IUSE="blaster buspirate dummy ftd2xx ftdi keil minidriver olimex parport \
	presto raisonance segger stlink usbprog verbose versaloon zylin"
RESTRICT="strip" # includes non-native binaries

# libftd2xx is the default because it is reported to work better.
DEPEND="dev-lang/jimtcl 
	blaster? ( dev-libs/libusb )  
	buspirate? ( dev-libs/libusb ) 
	keil? ( dev-libs/libusb ) 
	olimex? ( dev-libs/libusb ) 
	presto? ( dev-libs/libusb ) 
    raisonance? ( dev-libs/libusb ) 
    segger? ( dev-libs/libusb ) 
    stlink? ( dev-libs/libusb ) 
    usbprog? ( dev-libs/libusb ) 
	versaloon? ( dev-libs/libusb ) 
	ftd2xx? ( dev-embedded/libftd2xx ) 
	ftdi? ( dev-embedded/libftdi )"
RDEPEND="${DEPEND}"

REQUIRED_USE="blaster? ( || ( ftdi ftd2xx ) ) presto? ( || ( ftdi ftd2xx ) )
ftdi? ( !ftd2xx ) ftd2xx? ( !ftdi ) zylin? ( !minidriver ) minidriver? ( !zylin )"

src_prepare() {
	if [[ ${PV} == "9999" ]] ; then
		sed -i -e "/@include version.texi/d" doc/${PN}.texi || die
		AT_NO_RECURSIVE=yes eautoreconf
	fi
}

src_configure() {
	# Here are some defaults
	myconf="--enable-ioutil \
	--disable-werror \
	--disable-internal-jimtcl \
	--enable-ep93xx \
	--enable-at91rm9200 \
	--enable-gw16012 \
	--enable-oocd_trace"

	# add explicitely the path to libftd2xx
	use ftd2xx && LDFLAGS="${LDFLAGS} -L/opt/$(get_libdir)"

	if use blaster; then
		use ftdi && myconf="${myconf} --enable-usb_blaster_libftdi"
		use ftd2xx && myconf="${myconf} --enable-usb_blaster_ftd2xx"
	fi
	if use presto; then
		use ftdi && myconf="${myconf} --enable-presto_libftdi"
		use ftd2xx && myconf="${myconf} --enable-presto_ftd2xx"
	fi

	if use verbose; then
		myconf="${myconf} --enable-verbose --enable-verbose-jtag-io \
		--enable-verbose-usb-io --enable-verbose-usb-comms"
	fi

	if use parport; then
		myconf="${myconf} --enable-parport --enable-amtjtagaccel"
	fi

	econf \
		$(use_enable buspirate) \
		$(use_enable dummy) \
		$(use_enable ftdi ft2232_libftdi) \
		$(use_enable ftd2xx ft2232_ftd2xx) \
		$(use_enable keil ulink) \
		$(use_enable minidriver minidriver-dummy) \
		$(use_enable olimex arm-jtag-ew) \
		$(use_enable raisonance rlink) \
		$(use_enable segger jlink) \
		$(use_enable stlink) \
		$(use_enable usbprog) \
		$(use_enable versaloon vsllink) \
		$(use_enable zylin zy1000) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README TODO || die
	prepstrip "${D}"/usr/bin
}