Ebuild for gnumeric 1.2.11

gnumeric-1.2.11.ebuild (text/plain), 1.96 KB, created by Mikko Tiihonen on 2004-04-27 16:38:16 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/app-office/gnumeric/gnumeric-1.2.6.ebuild,v 1.5 2004/04/06 20:25:54 gmsoft Exp $

#provide Xmake and Xemake
inherit virtualx libtool gnome2 eutils flag-o-matic

DESCRIPTION="Gnumeric, the GNOME Spreadsheet"
HOMEPAGE="http://www.gnome.org/gnome-office/gnumeric.shtml"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="x86 ~ppc sparc hppa ~amd64 alpha ia64"

# evolution, perl, guile and gb support disabled currently (or to be removed)

# FIXME : should rethink gda/gnomedb USE stuff

#IUSE="libgda gnomedb python bonobo"
IUSE="libgda python bonobo"

RDEPEND=">=x11-libs/gtk+-2
	>=dev-libs/glib-2
	>=gnome-base/libgnome-2
	>=gnome-base/libgnomeui-2
	>=gnome-base/libgnomeprint-2.4.2
	>=gnome-base/libgnomeprintui-2.4.2
	>=gnome-base/libgnomecanvas-2
	>=gnome-base/libglade-2
	>=dev-libs/libxml2-2.4.12
	>=gnome-extra/libgsf-1.8.2
	>=media-libs/libart_lgpl-2.3.11
	python? ( >=dev-lang/python-2
		>=dev-python/pygtk-2 )
	libgda? ( >=gnome-extra/libgda-1.0.1 )
	bonobo? ( >=gnome-base/libbonobo-2.2
		>=gnome-base/libbonoboui-2.2 )"
#	gnomedb? ( >=gnome-extra/libgnomedb-0.90.2 )

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.30
	dev-util/pkgconfig
	>=sys-devel/autoconf-2.58"

src_unpack() {

	unpack ${A}
	gnome2_omf_fix

	cd ${S}
	# fix problems with libtool-0.28 generated stuff
	intltoolize --force

	export WANT_AUTOMAKE=1.7
	export WANT_AUTOCONF=2.5
	aclocal || die
	autoconf || die
	automake -a || die

}

src_compile() {

	# gcc bug (http://bugs.gnome.org/show_bug.cgi?id=128834)
	filter-flags "-Os"

	econf \
		`use_with bonobo` \
		`use_with python` \
		`use_with libgda gda` \
		|| die
	# `use_with gnomedb gda`

	# the build process has to be able to connect to X
	Xemake || die

}

src_install() {
	gnome2_src_install
	dosym /usr/share/${PN}/${PV}/share/gnome/help/gnumeric /usr/share/gnome/help/gnumeric/
}

DOCS="AUTHORS COPYING* ChangeLog HACKING NEWS README TODO"