# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit mozextension multilib versionator

MY_PV=$(delete_all_version_separators)
MY_P="OxygenKDE_$(replace_all_version_separators '_')"

DESCRIPTION="Oxygen style for Firefox"
HOMEPAGE="http://kde-look.org/content/show.php?content=117962"
SRC_URI="http://oxygenkde.altervista.org/download/${MY_P}.xpi"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

S=${WORKDIR}

src_unpack() {
	xpi_unpack "${MY_P}.xpi"
	xpi_unpack "./${MY_P}/oxykdeopt.xpi" "./${MY_P}/oxykdetheme.xpi"
}

src_prepare() {
	mv oxykdeopt {c2a3f51e-2920-4eab-9008-1bcb44d21d57}
	mv oxykdetheme {C1F83B1E-D6EE-11DE-B441-1AD556D89593}
}

src_install() {
	insinto /usr/$(get_libdir)/mozilla/extensions/{ec8030f7-c20a-464f-9b0e-13a3a9e97384}
	doins -r {c2a3f51e-2920-4eab-9008-1bcb44d21d57} {C1F83B1E-D6EE-11DE-B441-1AD556D89593}
	dohtml -r "{c2a3f51e-2920-4eab-9008-1bcb44d21d57}/chrome/oxygenkdeoptions/content/page/"*
}

pkg_postinst() {
	elog
	elog "To hide the firefox titlebar, read the instructions in /usr/share/doc/${P}/html/exceptionsguide.html"
	elog "or go to: http://oxygenkde.altervista.org/exceptionsguide.html"
}