# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=3

JAVA_PKG_IUSE="doc examples source"
inherit java-pkg-2 java-ant-2

DESCRIPTION="Java API To Access Microsoft Format Files"
HOMEPAGE="http://poi.apache.org/"
RELEASE_DATE="20101029"
SRC_URI="mirror://apache/poi/release/src/${PN}-src-${PV}-${RELEASE_DATE}.zip
	http://www.ecma-international.org/publications/files/ECMA-ST/Office%20Open%20XML%201st%20edition%20Part%204%20(PDF).zip"

LICENSE="Apache-2.0"
SLOT="3.7"
KEYWORDS="amd64 ppc ppc64 x86"
IUSE="test"

COMMON_DEPEND="
	>=dev-java/commons-logging-1.1
	=dev-java/xml-xmlbeans-2.3*
	>=dev-java/dom4j-1.6.1
	>=dev-java/junit-3.8.1
	>=dev-java/jsr173-1.0"
RDEPEND=">=virtual/jre-1.6
	${COMMON_DEPEND}"
DEPEND=">=virtual/jdk-1.6
	${COMMON_DEPEND}
	test? ( dev-java/ant-junit )"

#S=${WORKDIR}/${P}-FINAL

src_prepare() {
	#rm -v
	mkdir lib ooxml-lib
	mv ${WORKDIR}/Office* ooxml-lib
	java-pkg_jar-from --into lib commons-logging
	java-pkg_jar-from --into ooxml-lib xml-xmlbeans-2.3
	java-pkg_jar-from --into ooxml-lib dom4j-1
	java-pkg_jar-from --into ooxml-lib jsr173
	java-pkg_jar-from --into lib junit
	#java-pkg_jar-from --into lib commons-logging commons-logging.jar commons-logging-1.1.jar
	#use test && java-pkg_jar-from --into lib --build-only junit junit.jar junit-3.8.1.jar
	epatch "${FILESDIR}/compileXsds.patch"
	epatch "${FILESDIR}/fixJarNames.patch"
	epatch "${FILESDIR}/fixUserHome.patch"
	java-pkg_filter-compiler jikes
}

src_compile() {
	eant -Duser.home=`pwd` -Ddisconnected=true jar
	use doc && eant -Duser.home=`pwd` -Ddisconnected=true javadocs
#	eant -Duser.home=`pwd` -Ddisconnected=true docs
}

src_test() {
	ANT_TASKS="ant-junit" eant test-all -Ddisconnected=true -Duser.home=`pwd`
}



src_install() {
	use doc && java-pkg_dojavadoc build/tmp/site/build/site/apidocs
	use source && java-pkg_dosrc src/ooxml/java/org src/scratchpad/src/org src/java/org

	cd build/dist || die "Cannot change to dist directory"
	java-pkg_newjar poi-scratchpad-${PV}* ${PN}-scratchpad.jar
	java-pkg_newjar poi-ooxml-schemas-${PV}* ${PN}-ooxml-schemas.jar
	java-pkg_newjar poi-ooxml-${PV}* ${PN}-ooxml.jar
	use examples && java-pkg_newjar poi-examples-${PV}* ${PN}-examples.jar
	use examples && use source && java-pkg_dosrc src/examples/src/org
	java-pkg_newjar poi-${PV}* ${PN}.jar
}