An updated ebuild for sci-electronics/eagle-6.1.0

eagle-6.1.0.ebuild (text/plain), 2.93 KB, created by Maciej Grela on 2012-02-01 23:17:23 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit eutils

DESCRIPTION="CadSoft EAGLE schematic and printed circuit board (PCB) layout editor"
HOMEPAGE="http://www.cadsoft.de"

KEYWORDS="~amd64 ~x86"
IUSE="doc linguas_de linguas_zh"
LICENSE="cadsoft"
RESTRICT="strip test"
SLOT="0"

SRC_URI="ftp://ftp.cadsoft.de/eagle/program/${PV%\.[0-9]}/${PN}-lin-${PV}.run"

QA_DT_HASH="opt/eagle-${PV}/bin/eagle"

RDEPEND="sys-libs/glibc
	x11-libs/libXext
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	x86? ( media-libs/jpeg:62
		media-libs/libpng:1.2
		=dev-libs/openssl-0.9.8* )
	amd64? ( app-emulation/emul-linux-x86-baselibs
		app-emulation/emul-linux-x86-xlibs )"

# Append ${PV} since that's what upstream installs to
INSTALLDIR="/opt/eagle-${PV}"

case "${LINGUAS}" in
	*de*)
		MY_LANG="de";;
	*zh*)
		MY_LANG="zh";;
	*)
		MY_LANG="en";;
esac

# Single quotes are used to avoid substituting ${MY_LANG} at this point

# Mandatory documentation being installed
DOCS='README_${MY_LANG} UPDATE_${MY_LANG} library_${MY_LANG}.txt license_${MY_LANG}.txt'

# Extra documentation installed when 'doc' use flag is on
EXTRA_DOCS='eagle.dtd connect-device-split-symbol-${MY_LANG}.pdf elektro-tutorial.pdf make-symbol-device-package-bsdl-2011-${MY_LANG}.pdf manual_${MY_LANG}.pdf tutorial_${MY_LANG}.pdf'

src_unpack() {

	# Extract the built-in .tar.bz2 file starting at __DATA__
	sed  -e '1,/^__DATA__$/d' "${DISTDIR}/${A}" | tar xj || die "unpacking failed"

}

src_compile() {
	      :
}

src_install() {

	dodir ${INSTALLDIR}
	# Copy all to INSTALLDIR
	cp -r . "${D}"/${INSTALLDIR}

	make_wrapper eagle-${PV} "${INSTALLDIR}/bin/eagle" 

	# Install the documentation
	cd doc
	doman eagle.1

	# Add extra docs if needed
	use doc && DOCS="${DOCS} ${EXTRA_DOCS}"

	# Install docs in preferred language
	for doc in $DOCS; do
	    real_doc=$(eval echo $doc)

	    # Install an english version of the doc if native doesn't exist
	    [ ! -r "${real_doc}" ] && real_doc=$(MY_LANG="en" eval echo $doc)
	       
	    dodoc "${real_doc}"
	done

	# Remove docs left in INSTALLDIR
	rm -rf "${D}${INSTALLDIR}/doc"
	cd ..

	echo -e "PRELINK_PATH_MASK=${INSTALLDIR}" > "${S}/90eagle-${PV}"
	doenvd "${S}/90eagle-${PV}"

	# Create desktop entry
	mv bin/${PN}icon50.png bin/${PF}-icon50.png
	doicon bin/${PF}-icon50.png
	make_desktop_entry "${ROOT}/usr/bin/eagle-${PV}" "CadSoft EAGLE Layout Editor" ${PF}-icon50 "Graphics;Electronics"

}

pkg_postinst() {

	elog "Run \`env-update && source /etc/profile\` from within \${ROOT}"
	elog "now to set up the correct paths."
	elog "You must first run eagle as root to invoke product registration."
	echo
	ewarn "Due to some necessary changes in the data structure, once you edit"
	ewarn "a file with version 5.x you will no longer be able to edit it"
	ewarn "with versions prior to 5.0!"
	ewarn
	ewarn "Please read /usr/share/doc/${PF}/UPDATE_${MY_LANG} if you are upgrading from 4.xx."

}