# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

inherit autotools eutils multilib

DESCRIPTION="C library for image processing and analysis"
HOMEPAGE="http://www.leptonica.com/"
SRC_URI="http://www.leptonica.com/source/${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gif jpeg png static-libs tiff utils zlib"

DEPEND="gif? ( media-libs/giflib )
	jpeg? ( virtual/jpeg )
	png? ( media-libs/libpng )
	tiff? ( media-libs/tiff )
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}"

MY_DOCS=( README version-notes )

src_prepare() {
	#see #297101, error when enabling png and zlib
	if use png ; then
		epatch "${FILESDIR}"/${P}-zlib-include.patch
		eautoreconf
	fi

	# unhtmlize docs
	local docf
	for _docf in ${MY_DOCS[@]}; do
		awk '/<\/pre>/{s--} {if (s) print $0} /<pre>/{s++}' \
			${_docf}.html > ${_docf} || die 'awk failed'
		rm ${_docf}.html || die "rm failed"
	done
}

src_configure() {
	econf \
		$(use_with gif giflib) \
		$(use_with jpeg) \
		$(use_with png libpng) \
		$(use_with tiff libtiff) \
		$(use_with zlib) \
		$(use_enable utils programs) \
		$(use_enable static-libs static)
}

src_install() {
	default
	dodoc ${MY_DOCS[@]}
	rm "${ED}"/usr/$(get_libdir)/liblept.la || die 'removing .la failed'
}