SLOTed slony1 ebuild

slony1-2.0.7-r832.ebuild (text/plain), 1.90 KB, created by Vincent de Phily on 2012-01-16 16:56:51 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/slony1/slony1-2.0.7-r1.ebuild,v 1.1 2011/08/10 22:47:31 titanofold Exp $

EAPI="4"

inherit eutils

IUSE="doc perl"

DESCRIPTION="A replication system for the PostgreSQL Database Management System"
HOMEPAGE="http://slony.info/"

# ${P}-docs.tar.bz2 contains man pages as well as additional documentation
SRC_URI="http://main.slony.info/downloads/2.0/source/${P}.tar.bz2
		 http://main.slony.info/downloads/2.0/source/${P}-docs.tar.bz2"

LICENSE="BSD"
#SLOT="$(sed -r 's/r(.)(.).*/\1.\2/' <<< ${PR})"
SLOT="8.3"
KEYWORDS="~amd64 ~ppc ~x86"

DEPEND="!dev-db/slony1:0
		dev-db/postgresql-base:${SLOT}[threads]
		dev-db/postgresql-server:${SLOT}
		perl? ( dev-perl/DBD-Pg )"

pkg_setup() {
	if [[ ${SLOT//.} > 90 ]] ; then
		ewarn "You are building ${CATEGORY}/${PN} against a version of PostgreSQL greater than 9.0."
		ewarn "This is neither supported here nor upstream."
		ewarn "Any bugs you encounter should be reported upstream."
	fi
}

src_prepare() {
	epatch "${FILESDIR}/ldflags.patch"
}

src_configure() {
	econf $(use_with perl perltools) --with-pgconfigdir=/usr/lib/postgresql-${SLOT}/bin/
}

src_install() {
	sed -i "s@toolsbin=.*@toolsbin=/usr/lib/slony1-${SLOT}/bin/@" Makefile.global
	sed -i "s@slonbindir=.*@slonbindir=/usr/lib/slony1-${SLOT}/bin/@" Makefile.global
	emake DESTDIR="${D}" install

	dodoc HISTORY-1.1 INSTALL README SAMPLE TODO UPGRADING doc/howto/*.txt

	for i in "${S}"/doc/adminguide/man{1,7}/; do
		insinto /usr/share/slony1-${SLOT}/man/$(basename $i)
		doins ${i}/*
	done
	docompress /usr/share/slony1-${SLOT}/man

	if use doc ; then
		cd "${S}"/doc
		dohtml -r *
	fi

	newinitd <(sed "s/{SLOT}/${SLOT}/g" < "${FILESDIR}"/slony1.init) slony1-${SLOT}
	newconfd <(sed "s@LOGFILE=.*@LOGFILE=/var/log/slony1-${SLOT}.log@" "${FILESDIR}"/slony1.conf) slony1-${SLOT}
}