ebuild

pyside-1.1.0.ebuild (text/plain), 2.12 KB, created by Markos Chandras (RETIRED) on 2012-01-15 11:36:39 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/pyside-1.0.9.ebuild,v 1.1 2011/12/27 11:59:32 patrick Exp $

EAPI=3

PYTHON_DEPEND="2:2.5"

inherit base python cmake-utils virtualx

MY_P="${PN}-qt4.7+${PV}"

DESCRIPTION="Python bindings for the Qt framework"
HOMEPAGE="http://www.pyside.org/"
SRC_URI="http://www.pyside.org/files/${MY_P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug declarative help multimedia kde opengl script sql svg test webkit
X xmlpatterns"

QT_PV="4.7.0"

RDEPEND=">=x11-libs/qt-core-${QT_PV}
	help? ( >=x11-libs/qt-assistant-${QT_PV}[accessibility] )
	X? ( >=x11-libs/qt-gui-${QT_PV} )
	multimedia? ( >=x11-libs/qt-multimedia-${QT_PV} )
	opengl? ( >=x11-libs/qt-opengl-${QT_PV} )
	kde? ( media-libs/phonon )
	!kde? (
		|| (
			>=x11-libs/qt-phonon-${QT_PV}
			media-libs/phonon
		)
	)
	script? ( >=x11-libs/qt-script-${QT_PV} )
	sql? ( >=x11-libs/qt-sql-${QT_PV} )
	svg? ( >=x11-libs/qt-svg-${QT_PV}[accessibility] )
	test? ( >=x11-libs/qt-test-${QT_PV} )
	webkit? ( >=x11-libs/qt-webkit-${QT_PV} )
	xmlpatterns? ( >=x11-libs/qt-xmlpatterns-${QT_PV} )"

DEPEND="${RDEPEND}
	>=dev-python/shiboken-1.0.10"

S="${WORKDIR}/${MY_P}"

DOCS=( "ChangeLog" )

cmake-utils_use_build() {
	use ${1} || echo "-DDISABLE_${2:-$1}=1"
}

pkg_setup() {
	python_set_active_version 2
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_build test TESTS)
		$(cmake-utils_use_build X QtGui)
		$(cmake-utils_use_build X QtDesigner)
		$(cmake-utils_use_build X QtScriptTools)
		$(cmake-utils_use_build multimedia QtMultimedia)
		$(cmake-utils_use_build declarative QtDeclarative)
		$(cmake-utils_use_build opengl QtOpenGL)
		$(cmake-utils_use_build script QtScript)
		$(cmake-utils_use_build sql QtSql)
		$(cmake-utils_use_build svg QtSvg)
		$(cmake-utils_use_build test QtTest)
		$(cmake-utils_use_build webkit QtWebKit)
		$(cmake-utils_use_build xmlpatterns QtXmlPatterns)
		$(cmake-utils_use_build help QtHelp)
	)
	cmake-utils_src_configure
}

src_test() {
	VIRTUALX_COMMAND="cmake-utils_src_test"
	virtualmake
}