Updated live ebuild

gnome-shell-extensions-weather-9999.ebuild (text/plain), 1.56 KB, created by Reinis Danne on 2011-12-30 11:49:28 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="3"
PYTHON_DEPEND="2"

EGIT_REPO_URI="git://github.com/simon04/gnome-shell-extension-weather"

inherit gnome2-utils gnome2-live python

DESCRIPTION="Weather applet extension for GNOME Shell"
HOMEPAGE="https://github.com/simon04/gnome-shell-extension-weather"

LICENSE="GPL-3"
SLOT="0"
IUSE=""
KEYWORDS="" #"~amd64 ~x86"

COMMON_DEPEND="
	>=dev-libs/glib-2.26
	>=gnome-base/gnome-desktop-3:3
	app-admin/eselect-gnome-shell-extensions"
RDEPEND="${COMMON_DEPEND}
	gnome-base/gnome-desktop:3[introspection]
	gnome-base/gnome-shell
	media-libs/clutter:1.0[introspection]
	net-libs/telepathy-glib[introspection]
	x11-libs/gtk+:3[introspection]
	x11-libs/pango[introspection]"
DEPEND="${COMMON_DEPEND}
	sys-devel/gettext
	>=dev-util/pkgconfig-0.22
	>=dev-util/intltool-0.26
	gnome-base/gnome-common"

src_prepare() {
	gnome2_src_prepare

	python_convert_shebangs 2 *.py
}

src_install() {
	gnome2_src_install

	mv weather-extension-configurator{.py,}
	dobin weather-extension-configurator
}

pkg_postinst() {
	gnome2_pkg_postinst

	einfo "Updating list of installed extensions"
	eselect gnome-shell-extensions update || die
	elog
	elog "Installed extensions installed are initially disabled by default."
	elog "To change the system default and enable some extensions, you can use"
	elog "# eselect gnome-shell-extensions"
	elog "Alternatively, you can use the org.gnome.shell disabled-extensions"
	elog "gsettings key to change the disabled extension list per-user."
	elog
}