airstrike-1.0_pre6.ebuild

airstrike-1.0_pre6.ebuild (text/plain), 1.74 KB, created by Alexandru Toma on 2004-04-18 13:28:54 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games

MY_P="${P/1.0_/}a-src"
DESCRIPTION="A 2D dogfight game"
HOMEPAGE="http://icculus.org/airstrike/"
SRC_URI="http://icculus.org/airstrike/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE=""

RDEPEND=">=media-libs/libsdl-1.2
	>=media-libs/sdl-image-1.2
	>=media-libs/sdl-mixer-1.2"

DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

S="${WORKDIR}/${MY_P}"
DEST_DIR="${GAMES_DATADIR}/${PN}"

src_unpack() {
	unpack ${A}
	cd ${S}

	# Modify path to data files and enable sound
	sed -i \
		-e "/^datapath/s:data\":${DEST_DIR}/data\":" \
		-e "s:sound 0:sound 1:" \
		airstrikerc || die "sed airstrikerc failed"
	sed -i \
		-e "s:data/:${DEST_DIR}/data/:g" \
		src/airstrike.c || die "sed airstrike.c failed"

	# Modify path to configuration file
	sed -i \
		-e "s:\"airstrikerc\":\"${DEST_DIR}/airstrikerc\":" \
		src/config.h || "die sed config.h failed"

	# Modify chunksize to make sound more responsive
	sed -i \
		-e "s:4096:1024:" \
		src/sound.c || die "sed sound.c failed"

	# Modify CFLAGS
	sed -i \
		-e "s:-g -O2:${CFLAGS}:" \
		src/Makefile || "sed src/Makefile failed"
}

src_compile() {
	emake airstrike-sound || die "emake failed"
}

src_install() {
	insinto "${DEST_DIR}/data"
	doins data/* || die "doins failed"

	insinto "${DEST_DIR}/data/sound"
	doins data/sound/* || die "doins failed"

	dodoc ChangeLog README doc/{BUGS,TODO}
	doman doc/airstrike.6

	insinto "${DEST_DIR}"
	doins airstrikerc || die "doins failed"

	dogamesbin airstrike || die "dogamesbin failed"

	prepgamesdirs
}

pkg_postinst() {
	einfo "If you wish to modify the configuration copy"
	einfo "${DEST_DIR}/airstrikerc to ~/.airstrikerc and edit it"
}