xine-ui-0.9.23-r1.ebuild

xine-ui-0.9.23-r1.ebuild (text/plain), 1.67 KB, created by Diego Elio Pettenò (RETIRED) on 2004-04-16 03:32:36 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/cvsroot/gentoo-x86/media-video/xine-ui/xine-ui-0.9.23-r1.ebuild,v 1.3 2004/04/14 15:49:13 swtaylor Exp $

inherit eutils

DESCRIPTION="Xine movie player"
HOMEPAGE="http://xine.sourceforge.net/"
SRC_URI="mirror://sourceforge/xine/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc amd64 ~alpha"
IUSE="X gnome nls directfb lirc aalib"

DEPEND="media-libs/libpng
	>=media-libs/xine-lib-1_rc3
	>=net-misc/curl-7.10.2
	lirc? ( app-misc/lirc )
	X? ( virtual/x11 )
	aalib? ( media-libs/aalib )
	gnome? ( gnome-base/ORBit )
	directfb? ( media-libs/aalib
		>=dev-libs/DirectFB-0.9.9 )"
RDEPEND="nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/symlink-bug.patch
	epatch ${FILESDIR}/preserve-CFLAGS-${PV}.diff
	epatch ${FILESDIR}/true-false.patch
	use directfb || sed -i "s:dfb::" src/Makefile.in
	sed -i "s:LDFLAGS =:LDFLAGS = -L/lib:" src/xitk/Makefile.in
}

src_compile() {
	rm misc/xine-bugreport
	local myconf=""
	use X || myconf="${myconf} --disable-x11 --disable-xv"
	use nls || myconf="${myconf} --disable-nls"
	use lirc || myconf="${myconf} --disable-lirc"
	econf ${myconf} || die
	emake || die
}

src_install() {
	make DESTDIR=${D} \
		docdir=/usr/share/doc/${PF} \
		docsdir=/usr/share/doc/${PF} \
		install || die

	dodoc AUTHORS ChangeLog INSTALL NEWS README
}

pkg_setup() {
	if has_version 'media-libs/aalib' && [ -z "`use aalib`" ]; then
			ewarn "aalib will be detected by the package and support will be enabled"
			ewarn "The package presently provides no way to disable aalib support if you don't want it"
	fi
						
}