gpsd-3.3.ebuild

gpsd-3.3.ebuild (text/plain), 2.58 KB, created by SpanKY on 2011-11-18 05:00:11 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-2.96-r1.ebuild,v 1.2 2011/07/18 07:09:17 scarabeus Exp $

EAPI="4"

PYTHON_DEPEND="2:2.6"
SCONS_MIN_VERSION="1.2.1"

inherit eutils user multilib python scons-utils toolchain-funcs

DESCRIPTION="GPS daemon and library to support USB/serial GPS devices and various GPS/mapping clients"
HOMEPAGE="http://catb.org/gpsd/"
SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

GPSD_PROTOCOLS=(
	ashtech aivdm clientdebug earthmate evermore fv18 garmin
	garmintxt gpsclock itrax mtk3301 nmea ntrip navcom oceanserver
	oldstyle oncore rtcm104v2 rtcm104v3 sirf superstar2 timing tsip
	tripmate tnt ubx
)
IUSE_GPSD_PROTOCOLS=${GPSD_PROTOCOLS[@]/#/gpsd_protocols_}
IUSE="${IUSE_GPSD_PROTOCOLS} bluetooth cxx debug dbus ipv6 ncurses ntp qt4 test udev usb"

#dev-python/pygtk:2
RDEPEND="
	ncurses? ( sys-libs/ncurses )
	bluetooth? ( net-wireless/bluez )
	usb? ( virtual/libusb:1 )
	dbus? (
		sys-apps/dbus
		dev-libs/dbus-glib
	)
	ntp? ( net-misc/ntp )
	qt4? ( x11-libs/qt-gui )"
# xml packages are for man page generation
DEPEND="${RDEPEND}
	app-text/xmlto
	=app-text/docbook-xml-dtd-4.1*
	test? ( sys-devel/bc )"

pkg_setup() {
	python_set_active_version 2

	# Run the gpsd daemon as gpsd and group uucp
	enewuser gpsd -1 -1 -1 "uucp"
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-release-rev.patch
	epatch "${FILESDIR}"/${P}-udev-install.patch

	# Avoid useless chrpath usage, and useless -L paths
	sed -i \
		-e '/env.Prepend.*LIBPATH=.*installdir/s:env.*:pass:' \
		-e '/env.Prepend.*RPATH=/s:env.*:pass:' \
		SConstruct || die
}

gpsd_scons() {
	local myopts protocol

	# enable specified protocols
	for protocol in ${GPSD_PROTOCOLS[@]} ; do
		myopts+=" $(use_scons gpsd_protocols_${protocol} ${protocol})"
	done

	escons \
		prefix=/usr \
		libdir="/$(get_libdir)" \
		gpsd_user=gpsd \
		gpsd_group=uucp \
		strip=False \
		python=False \
		$(use_scons bluetooth bluez) \
		$(use_scons cxx libgpsmm) \
		$(use_scons debug) \
		$(use_scons dbus dbus-export) \
		$(use_scons ipv6) \
		$(use_scons ncurses) \
		$(use_scons ntp ntpshm) \
		$(use_scons ntp pps) \
		$(use_scons qt4 libQgpsmm) \
		$(use_scons usb) \
		${myopts} \
		"$@"
}

src_compile() {
	export CHRPATH=true
	tc-export CC CXX
	export SHLINKFLAGS=${LDFLAGS} LINKFLAGS=${LDFLAGS}
	gpsd_scons
}

src_install() {
	DESTDIR="${D}" gpsd_scons install $(usex udev udev-install "")

	newconfd "${FILESDIR}"/gpsd.conf-2 gpsd
	newinitd "${FILESDIR}"/gpsd.init-2 gpsd
}