ebuild with additional run-time depenencies.

zim-0.53.ebuild (text/plain), 1.68 KB, created by Alastair Murray on 2011-11-17 00:43:54 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/zim-0.52.ebuild,v 1.1 2011/05/30 21:41:41 xmw Exp $

PYTHON_USE_WITH="sqlite"
PYTHON_DEPEND="2:2.5"

EAPI=3

inherit distutils eutils fdo-mime virtualx

DESCRIPTION="A desktop wiki"
HOMEPAGE="http://zim-wiki.org/"
SRC_URI="http://zim-wiki.org/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bazaar gnuplot graphviz imagemagick latex R screenshot spell test"

RDEPEND="${DEPEND}
	bazaar? ( dev-vcs/bzr )
	gnuplot? ( sci-visualization/gnuplot )
	graphviz? ( media-gfx/graphviz )
	imagemagick? ( media-gfx/imagemagick )
	latex? ( virtual/latex-base app-text/dvipng )
	R? ( dev-lang/R )
	screenshot? ( media-gfx/scrot )
	spell? ( dev-python/gtkspell-python )"
DEPEND="|| ( >=dev-lang/python-2.6 dev-python/simplejson )
	dev-python/pygtk
	x11-misc/xdg-utils"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	sed -i -e "s/'USER'/'LOGNAME'/g" zim/__init__.py zim/fs.py || die
}

src_test() {
	VIRTUALX_COMMAND="$(PYTHON)" virtualmake test.py || die
}

src_install () {
	doicon data/${PN}.png || die "doicon failed"
	distutils_src_install --skip-xdg-cmd
}

pkg_postinst() {
	distutils_pkg_postinst
	fdo-mime_desktop_database_update
	xdg-icon-resource install --context mimetypes --size 64 \
		"${ROOT}/usr/share/pixmaps/zim.png" \
		application-x-zim-notebook || die "xdg-icon-resource install failed"
}

pkg_postrm() {
	distutils_pkg_postrm
	fdo-mime_desktop_database_update
	xdg-icon-resource uninstall --context mimetypes --size 64 \
		application-x-zim-notebook || die "xdg-icon-resource uninstall failed"
}