gnome-mplayer-1.0.4-r1.ebuild

gnome-mplayer-1.0.4-r1.ebuild (text/plain), 2.68 KB, created by Samuel Bauer on 2011-11-11 23:39:42 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.4.ebuild,v 1.4 2011/10/15 17:20:40 ssuominen Exp $

EAPI=4
inherit autotools eutils fdo-mime gnome2-utils

DESCRIPTION="A GTK+ interface to MPlayer"
HOMEPAGE="http://code.google.com/p/gnome-mplayer/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="alsa dbus dconf gconf gnome gtk3 ipod libnotify musicbrainz pulseaudio"

COMMON_DEPEND=">=dev-libs/glib-2.26:2
	gtk3? ( x11-libs/gtk+:3 )
	!gtk3? ( x11-libs/gtk+:2 )
	x11-libs/libX11
	x11-libs/libXScrnSaver
	alsa? ( media-libs/alsa-lib )
	dbus? ( >=dev-libs/dbus-glib-0.92 )
	gnome? ( gnome-base/nautilus )
	ipod? ( >=media-libs/libgpod-0.7 )
	libnotify? ( x11-libs/libnotify )
	musicbrainz? ( net-misc/curl
		>=media-libs/musicbrainz-3 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )"
RDEPEND="${COMMON_DEPEND}
	|| ( >=media-video/mplayer-1.0_rc4_p20100101[ass] media-video/mplayer2[ass] )
	dconf? ( gnome-base/dconf )
	!dconf? ( gconf? ( gnome-base/gconf ) )
	gnome? ( gnome-base/gvfs )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

DOCS="ChangeLog README DOCS/keyboard_shortcuts.txt DOCS/tech/dbus.txt DOCS/tech/plugin-interaction.txt"

src_prepare() {
	epatch "${FILESDIR}"/${P}-noalsa.patch

	if ! use dconf && ! use gconf; then
		sed -i \
			-e 's/USE_GSETTINGS=1/USE_GSETTINGS=0/g' \
			-e 's/with_gsettings=yes/with_gsettings=no/g' \
				configure.in
		eautoconf
	fi
}

src_configure() {
	# FIXME: The only reason why --without-gpm-new-method is passed is lack of testing.
	myconf="${myconf} --without-gpm-new-method"
	myconf="${myconf} --without-gpm-old-method"
	myconf="${myconf} --disable-gseal"
	if use dconf || use gconf; then
		myconf="${myconf} --with-gio"
	else
		myconf="${myconf} --without-gio"
	fi

	econf \
		$(use_enable gtk3) \
		$(use_enable gnome nautilus) \
		$(use_with gconf ) \
		$(use_with dbus) \
		$(use_with alsa) \
		$(use_with pulseaudio) \
		$(use_with libnotify) \
		$(use_with ipod libgpod) \
		$(use_with musicbrainz libmusicbrainz3) \
		${myconf}
}

src_install() {
	default
	#if ! use dconf && ! use gconf; then
	#	insinto /usr/share/glib-2.0/schemas
	#	doins apps*xml
	#fi
	rm -rf "${ED}"/usr/share/doc/${PN}
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update --uninstall
}