ebuild 2.2.2

latexila-2.2.2.ebuild (text/plain), 1.85 KB, created by Sébastien Wilmet on 2011-10-30 17:55:29 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=4

CMAKE_MIN_VERSION="2.6.4"

inherit gnome.org gnome2-utils cmake-utils fdo-mime

DESCRIPTION="An Integrated LaTeX Environment for GNOME"
HOMEPAGE="http://projects.gnome.org/latexila/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86"

IUSE="gnome"

common_depend="
	>=dev-libs/glib-2.28:2
	>=x11-libs/gtk+-2.16:2
	>=x11-libs/gtksourceview-2.10:2.0
	dev-libs/libgee
	dev-libs/libunique:1
	sys-devel/gettext
	gnome? ( gnome-base/gsettings-desktop-schemas )
"

DEPEND="
	${common_depend}
	>=dev-lang/vala-0.12.1:0.12
	dev-util/itstool
	dev-util/pkgconfig
"

RDEPEND="
	${common_depend}
	x11-themes/hicolor-icon-theme
	virtual/latex-base
"

pkg_setup() {
	DOCS=( AUTHORS HACKING INSTALL NEWS README TODO )
}

src_prepare() {
	# Linguas: remove useless *.po
	local po_files=$(find . -name '*.po')
	local po_file
	for po_file in ${po_files}; do
		local lang=$(basename ${po_file} .po)

		if ! has ${lang} ${LINGUAS}; then
			rm ${po_file}
		fi
	done

	# Build from Vala sources
	rm src/C/*.c
}

src_configure() {
	local mycmakeargs="
		$(cmake-utils_use_with gnome GNOME)
		-DCOMPILE_SCHEMA=OFF
		-DBUILD_VALA=ON
	"
	cmake-utils_src_configure
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update

	elog ""
	elog "For compiling a LaTeX document, LaTeXila uses by default Latexmk."
	elog "Rubber or the \"low-level\" commands such as \"pdflatex\", \"dvipdf\" or \"bibtex\""
	elog "can also be used."
	elog ""
	elog "So you most probably want to install dev-tex/latexmk or dev-tex/rubber now."
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update --uninstall
}