# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit perl-module webapp

DESCRIPTION="SendmailAnalyzer is a free Sendmail/Postfix log analyzer"
HOMEPAGE="http://sareport.darold.net/"
SRC_URI="mirror://sourceforge/sa-report/${PV}/${P}.tar.gz"

LICENSE="GPL-3"
KEYWORDS="~amd64"
IUSE="daemon"
SLOT="0"
WEBAPP_MANUAL_SLOT="yes"

# Note: we can ignore MIME::QuotedPrint, because perl itself ships it
RDEPEND=">=dev-lang/perl-5.8.0
	virtual/perl-MIME-Base64
	dev-perl/GD[png]
	dev-perl/GDGraph
	dev-perl/GDTextUtil
	dev-perl/GD-Graph3d
	virtual/cron"


DATADIRECTORY="/var/db/sendmailanalyzer"

need_httpd_cgi

src_configure() {
	# set variables	
	myconf="
		QUIET=1
		LOGFILE=/var/log/mail.log
		BINDIR=/usr/bin
		CONFDIR=/etc/sendmailanalyzer
		BASEDIR=${DATADIRECTORY}
		HTMLDIR=${MY_CGIBINDIR}
		DOCDIR=/usr/share/doc/${P}
		MANDIR=/usr/share/man/man3"

	# run configuration script
	perl-module_src_configure
}

src_install() {
	# create data directory
	keepdir ${DATADIRECTORY}

	# support daemon support
	if use daemon; then
		# install init.d file
		newinitd ${FILESDIR}/${PN}.init ${PN}
	fi

	# install sa_cache cron job
	exeinto /etc/cron.daily
	newexe "${FILESDIR}/sendmailanalyzer.cron" sendmailanalyzer.cron

	# install usual stuff
	perl-module_src_install

	# install web stuff
	webapp_src_preinst

	webapp_serverowned ${MY_CGIBINDIR}/sa_report.cgi
	webapp_serverowned ${MY_CGIBINDIR}/grafit.cgi

	webapp_hook_script ${FILESDIR}/chmod-hook.sh

	webapp_src_install
}

pkg_postinst() {
	# print installation instructions
	webapp_postinst_txt en "${FILESDIR}/postinstall-en.txt"

	# call webapp's pkg_postinst
	webapp_pkg_postinst
}