# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic

EAPI="2"
DESCRIPTION="An Open Source MQTT v3 Broker"
HOMEPAGE="http://mosquitto.org/"

if [[ "${PV}" == "${PV%%_rc[0-9]}" ]]; then
	SRC_URI="http://mosquitto.org/files/source/${P}.tar.gz"
else
	SRC_URI="http://mosquitto.org/files/source/rc/${P/_/~}.tar.gz"
	S="${WORKDIR}/${P/_/~}"
fi

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="tcpd bridge dbupgrade +persistence"
RDEPEND="dbupgrade? ( dev-db/sqlite:3 )
		tcpd? ( sys-apps/tcp-wrappers )"
DEPEND="${RDEPEND}"

src_configure() {
	if use tcpd ; then
		sed -i 's/\(^LDFLAGS=.*\)/\1 -lwrap/' config.mk
		sed -i 's/^\/\/#define WITH_WRAP/#define WITH_WRAP/' config.h
	fi
	if use dbupgrade ; then
		sed -i 's/^\/\/#define WITH_DB_UPGRADE/#define WITH_DB_UPGRADE/' config.h
	fi
	if ! use bridge ; then
		sed -i 's/^#define WITH_BRIDGE/\/\/#define WITH_BRIDGE/' config.h
	fi
}

src_install() {
	emake install DESTDIR="${D}" prefix=/usr || die "Install failed"
	dodir /var/lib/mosquitto
	dodoc readme.txt ChangeLog.txt || die "dodoc failed"
	doinitd "${FILESDIR}"/mosquitto
	if use persistence; then
		dosed "s:^#autosave_interval:autosave_interval:" /etc/mosquitto/mosquitto.conf
		dosed "s:^#persistence false$:persistence true:" /etc/mosquitto/mosquitto.conf
		dosed "s:^#persistence_file:persistence_file:" /etc/mosquitto/mosquitto.conf
		dosed "s:^#persistence_location$:persistence_location /var/lib/mosquitto/:" /etc/mosquitto/mosquitto.conf
	fi
}

pkg_setup() {
	enewuser mosquitto
}

pkg_postinst() {
	chown mosquitto: /var/lib/mosquitto
	elog "To start mosquitto at boot, add it to the default runlevel with:"
	elog ""
	elog "    rc-update add mosquitto default"
}