gpsd-3.1.ebuild

gpsd-3.1.ebuild (text/plain), 2.45 KB, created by Ed Wildgoose on 2011-09-09 16:43:54 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-2.96-r1.ebuild,v 1.2 2011/07/18 07:09:17 scarabeus Exp $

EAPI=3

PYTHON_DEPEND="2:2.6"
SCONS_MIN_VERSION="1.2.1"

inherit base eutils python scons-utils

DESCRIPTION="GPS daemon and library to support USB/serial GPS devices and various GPS/mapping clients."
HOMEPAGE="http://gpsd.berlios.de/"
SRC_URI="mirror://berlios/gpsd/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

GPSD_PROTOCOLS="ashtech aivdm clientdebug earthmate evermore fv18 garmin
	garmintxt gpsclock itrax mtk3301 nmea ntrip navcom oceanserver
	oldstyle oncore rtcm104v2 rtcm104v3 sirf superstar2 timing tsip
	tripmate tnt ubx"
for protocol in ${GPSD_PROTOCOLS}; do
	IUSE_GPSD_PROTOCOLS+=" gpsd_protocols_${protocol}"
done

IUSE="${IUSE_GPSD_PROTOCOLS} debug dbus ipv6 ntp qt4 test udev"

# those harddeps are de-facto automagicall
RDEPEND="
	dev-python/pygtk:2
	sys-libs/ncurses
	virtual/libusb:1
	dbus? (
		sys-apps/dbus
		dev-libs/dbus-glib
	)
	ntp? ( net-misc/ntp )
	qt4? ( x11-libs/qt-gui )"

DEPEND="${RDEPEND}
	app-text/xmlto
	=app-text/docbook-xml-dtd-4.1*
	test? ( sys-devel/bc )"

#PATCHES=(
#)

pkg_setup() {
	python_set_active_version 2

	# Run the gpsd daemon as gpsd and group uucp
	enewuser gpsd -1 -1 -1 "uucp"
}

src_compile() {
	local myopts

	# enable specified protocols
	for protocol in ${GPSD_PROTOCOLS}; do
		myopts+=" $(use_scons gpsd_protocols_${protocol} ${protocol})"
	done

	if ! use qt4 ; then
		myopts+=" libQgpsmm=False libgpsmm=False"
	fi

	escons \
		gpsd-user=gpsd \
		gpsd-group=uucp \
		strip=False \
		$(use_scons debug) \
		$(use_scons dbus dbus-export) \
		$(use_scons ipv6) \
		$(use_scons ntp ntpshm) \
		$(use_scons ntp pps) \
		${myopts}
}

src_install() {
	# STRIP= is a hack to prevent the scons build stripping binaries. 
	# gpsd 3.1+ expected to support strip flag to control stripping
	DESTDIR="${D}" STRIP="/bin/true" escons prefix="/usr/" install || die

	if use udev ; then
		insinto /lib/udev/rules.d/
		newins gpsd.rules 25-gpsd.rules
		exeinto /lib/udev/
		doexe gpsd.hotplug{,.wrapper}
	fi

	# needs this header for libQgpsmm
	if use qt4 ; then
		insinto /usr/include
		doins libQgpsmm/libQgpsmm_global.h
	fi

	# no need for .la files here
	find "${D}" -type f -name '*.la' -exec rm -f '{}' +

	newconfd "${FILESDIR}"/gpsd.conf-2 gpsd || die
	newinitd "${FILESDIR}"/gpsd.init-2 gpsd || die
}