sci-electronics/kicad-20110708 ebuild

kicad-20110708_p3044.ebuild (text/plain), 5.63 KB, created by Jacek Szafarkiewicz on 2011-09-02 10:17:47 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/kicad/kicad-20100505_p2356.ebuild,v 1.3 2010/12/25 21:37:38 rafaelmartins Exp $

# rafaelmartins: Please try to keep the live ebuild synchronized with
# the latest snapshot ebuild. e.g.:
# cp kicad-YYYYMMDD_pXXXX.ebuild kicad-99999999.ebuild

EAPI="4"

DOCS_AND_TRANS_V="2011-07-04"
LIBRARY_V="20100505_p2356"

WX_GTK_VER="2.8"

inherit cmake-utils wxwidgets fdo-mime gnome2-utils

DESCRIPTION="Electronic Schematic and PCB design tools."
HOMEPAGE="http://kicad.sourceforge.net"

if [[ "${PV}" != "99999999" ]]; then
	PV_DATE=$(echo ${PV} | sed 's:\(....\)\(..\)\(..\).*:\1-\2-\3:')
	PV_BZR=$(echo ${PV} | sed 's:.*_p\(.*\):\1:')

	SRC_URI="
		http://iut-tice.ujf-grenoble.fr/cao/sources/${PN}_sources-${PV_DATE}-BZR${PV_BZR}.zip
		http://iut-tice.ujf-grenoble.fr/cao/docs_and_translations_${PN}_${DOCS_AND_TRANS_V}.zip
		!minimal? ( http://dev.gentoo.org/~rafaelmartins/distfiles/${PN}-library-${LIBRARY_V}.tar.xz )"

	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"

	S="${WORKDIR}/${PN}_sources-${PV_DATE}_BZR${PV_BZR}"
else
	SRC_URI=""
	EBZR_REPO_URI="lp:kicad"
	EBZR_REPO_URI_LIB="lp:~kicad-lib-committers/kicad/library"
	EBZR_REPO_URI_DOC="lp:~kicad-lib-committers/kicad/doc"

	KEYWORDS=""

	inherit bzr
fi

LICENSE="GPL-2"
SLOT="0"

IUSE="dev-doc debug doc examples minimal python"

# This may be useful in the future (dynamic lang)
#if [[ "${PV}" != "99999999" ]]; then
#	LANGS=(ca cs de el_GR es fi fr hu it ja ko nl pl pt ru sl sv zh_CN)
#
#	for X in ${LANGS[@]}; do
#		IUSE="${IUSE} linguas_${X}"
#	done
#fi



CDEPEND="x11-libs/wxGTK:2.8[X,opengl]"
DEPEND="${CDEPEND}
	>=dev-util/cmake-2.6.0
	>=dev-libs/boost-1.40[python?]
	app-arch/xz-utils
	dev-doc? ( app-doc/doxygen )"
RDEPEND="${CDEPEND}
	sys-libs/zlib
	sci-electronics/electronics-menu"

src_unpack() {
	if [[ "${PV}" != "99999999" ]]; then
		default
	else
		bzr_fetch

		# FIXME: we need to send patches for bzr.eclass, to avoid the weird
		# declarations of ${P} below.
		if ! use minimal; then
			EBZR_REPO_URI="${EBZR_REPO_URI_LIB}" \
				P="${P}/kicad-library" \
				EBZR_CACHE_DIR="kicad-library" bzr_fetch
		fi
		if use doc; then
			EBZR_REPO_URI="${EBZR_REPO_URI_DOC}" \
				P="${P}/kicad-doc" \
				EBZR_CACHE_DIR="kicad-doc" bzr_fetch
		fi
	fi
}

src_prepare() {
	# prepare sources from BZR, snapshots are already prepared with this
	if [[ "${PV}" = "99999999" ]]; then
		sed -i \
			-e '/add_subdirectory(template)/ a \
				add_subdirectory(kicad-doc)\
				add_subdirectory(kicad-library)' \
			-e 's/create_svn_version_header()/#create_svn_version_header()/' \
			-e 's/ -O2 / /' \
			CMakeLists.txt || die 'sed failed'
		sed -i \
			-e 's/Scientific;Development/Engineering;Electronics/' \
			resources/linux/mime/applications/*.desktop || die 'sed failed'
	fi

	# Use native boost
	sed -i -e '/Boost/s/^#check_find_package/check_find_package/' \
		-e '/Boost/s/^#find_package/find_package/' CMakeLists.txt || die "sed failed"

	# Add important doc files
	sed -i -e 's/INSTALL.txt/AUTHORS.txt CHANGELOG.txt README.txt TODO.txt/' CMakeLists.txt || die "sed failed"

	# Fix desktop files
	rm resources/linux/mime/applications/eeschema.desktop
	sed -i -e 's/Development;//' resources/linux/mime/applications/kicad.desktop || die "sed failed"

	# Handle optional minimal install
	if use minimal ; then
		sed -i -e '/add_subdirectory(template)/d' \
			-e '/add_subdirectory(kicad-library)/d' CMakeLists.txt || die "sed failed"
	fi

	# Install examples in the right place if requested
	if use examples ; then
		sed -i -e 's:${KICAD_DATA}/demos:${KICAD_DOCS}/examples:' CMakeLists.txt || die "sed failed"
	else
		sed -i -e '/add_subdirectory(demos)/d' CMakeLists.txt || die "sed failed"
	fi
}

src_configure() {
	need-wxwidgets unicode

	mycmakeargs="${mycmakeargs}
		-DKICAD_MINIZIP=OFF
		-DKICAD_CYRILLIC=ON
		-DwxUSE_UNICODE=ON
		-DKICAD_GOST=OFF
		-DKICAD_AUIMANAGER=OFF
		-DKICAD_AUITOOLBAR=OFF
		-DKICAD_DOCS=/usr/share/doc/${PF}
		-DKICAD_HELP=/usr/share/doc/${PF}
		$(cmake-utils_use python KICAD_PYTHON)
		$([ "${PV}" != "99999999" ] && echo -DKICAD_STABLE_VERSION=ON || echo -DKICAD_TESTING_VERSION=ON)"

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	use dev-doc && doxygen Doxyfile
}

src_install() {
	cmake-utils_src_install

	if [ "${PV}" != "99999999" ]; then
		rm "${WORKDIR}"/doc/internat/CMakeLists.txt

		insinto /usr/share/${PN}/internat
		doins -r "${WORKDIR}"/doc/internat/*

# This may be useful in the future (dynamic lang)
#	    for X in ${LANGS[@]}; do
#	        if use linguas_${X}; then
#				doins -r "${WORKDIR}/doc/internat/${X}"
#			fi
#	    done

		if use doc; then
			dodoc -r "${WORKDIR}"/doc/doc/*
		fi
	fi


	if use dev-doc ; then
		dodoc uncrustify.cfg
		cd Documentation
		dodoc -r GUI_Translation_HOWTO.pdf guidelines/UIpolicies.txt doxygen/doxygen
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update

	if use minimal ; then
		ewarn "If the schematic and/or board editors complain about missing libraries when you"
		ewarn "open old projects, you will have to take one or more of the following actions :"
		ewarn "- Install the missing libraries manually."
		ewarn "- Remove the libraries from the 'Libs and Dir' preferences."
		ewarn "- Fix the libraries' locations in the 'Libs and Dir' preferences."
		ewarn "- Emerge kicad without the 'minimal' USE flag."
		elog
	fi

	elog "You may want to emerge media-gfx/wings if you want to create 3D models of components."
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}