games-emulation/ssnes-0.7.ebuild

ssnes-0.7.ebuild (text/plain), 1.70 KB, created by Jared B. on 2011-08-27 20:25:56 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit games confutils git

MY_PN=SSNES

DESCRIPTION="Simple SNES emulator frontend based on libsnes"
HOMEPAGE="https://github.com/Themaister/SSNES"
SRC_URI=""

EGIT_REPO_URI="git://github.com/Themaister/${MY_PN}.git"
EGIT_COMMIT="v${PV}-fix"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64"
IUSE="alsa cg dynamic fbo ffmpeg image jack libsamplerate netplay openal oss pulseaudio python3 truetype xml xv"

RDEPEND="media-libs/libsdl[joystick]
	alsa? ( media-libs/alsa-lib )
	cg? ( media-gfx/nvidia-cg-toolkit )
	ffmpeg? ( virtual/ffmpeg )
	jack? ( media-sound/jack-audio-connection-kit )
	openal? ( media-libs/openal )
	xml? ( dev-libs/libxml2 )
	truetype? ( media-libs/freetype:2 )
	pulseaudio? ( media-sound/pulseaudio )
	libsamplerate? ( media-libs/libsamplerate )
	!dynamic? ( || ( dev-games/libsnes
		dev-games/snes9x-libsnes ) )"
DEPEND="dev-util/pkgconfig
	${RDEPEND}"

pkg_setup() {
	confutils_require_any alsa jack openal oss pulseaudio
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-build-0.7.patch"
}

src_configure() {
	egamesconf \
		$(use_enable dynamic) \
		$(use_enable ffmpeg) \
		$(use_enable netplay) \
		$(use_enable libsamplerate src) \
		$(use_enable cg) \
		$(use_enable xml) \
		$(use_enable fbo) \
		$(use_enable alsa) \
		$(use_enable oss) \
		$(use_enable openal al) \
		$(use_enable jack) \
		$(use_enable pulseaudio pulse) \
		$(use_enable truetype freetype) \
		$(use_enable xv xvideo) \
		$(use_enable image sdl_image) \
		$(use_enable python3 python) \
		|| die "configure"
}

src_install() {
	emake DESTDIR="${D}" install || die "install"
	dodoc README.md AUTHORS
	prepgamesdirs
}