net-wireless/rtlwifi-0003.0620.2011.ebuild

rtlwifi-0003.0620.2011.ebuild (text/plain), 1.37 KB, created by Peter Gantner (a.k.a. nephros) on 2011-08-05 12:06:48 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/rtl8192se/rtl8192se-2.6.0018.1013.2010.ebuild,v 1.2 2010/10/23 11:53:46 chithanh Exp $

EAPI=3

inherit base linux-info linux-mod

MY_P="92ce_se_de_linux_mac80211_${PV}"

DESCRIPTION="RTL8191CE/DE/SE wireless chipset driver"
HOMEPAGE="http://www.realtek.com.tw/"
SRC_URI="mirror://gentoo/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="+firmware"

DEPEND=""
RDEPEND="${DEPEND}
	!net-wireless/rtl8192se"

# might block this as well, but OTOH it's harmless:
#RDEPEND="${RDEPEND}
#	firmware? ( !net-wireless/rtl8192se-firmware )"

S=${WORKDIR}/rtl_92ce_92se_92de_linux_mac80211_${PV}

CONFIG_CHECK="CFG80211 MAC80211 ~WIRELESS_EXT"

MODULE_NAMES="rtlwifi(net::)
rtl8192ce(net::${S}/rtl8192ce)
rtl8192de(net::${S}/rtl8192de)
rtl8192se(net::${S}/rtl8192se)"
BUILD_TARGETS="all"

src_prepare() {
	kernel_is -ge 2 6 35
	base_src_prepare
}

src_install() {
	if use firmware; then
		einfo "installing firmware"
		einfo "NOTE: There a licensing restrictions on the firmware, be sure to"
		einfo "read Realtek-Firmware-License.txt located in the doc dir of this"
		einfo "package!"

		insinto /lib/firmware/rtlwifi
		doins -r firmware/rtlwifi/*.bin
		dodoc firmware/rtlwifi/Realtek-Firmware-License.txt
	fi

	linux-mod_src_install
}