worldofpadman-1.5-r1.ebuild

worldofpadman-1.5-r1.ebuild (text/plain), 2.61 KB, created by Holger Thon on 2011-07-07 19:33:04 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/worldofpadman/worldofpadman-1.2-r1.ebuild,v 1.3 2010/05/23 18:34:54 pacho Exp $

EAPI=2
inherit eutils games

MY_P=wop-engine-1.2
MY_DATA=wop-1.5-unified.zip
DESCRIPTION="A cartoon style multiplayer first-person shooter"
HOMEPAGE="http://worldofpadman.com/"
SRC_URI="ftp://kickchat.com/wop/${MY_P}.tar.bz2
	mirror://sourceforge/${PN}/${MY_DATA}
	maps? ( http://thilo.kickchat.com/download/wop_padpack.zip )"

LICENSE="GPL-2 worldofpadman"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="dedicated maps openal opengl"

UIDEPEND="virtual/opengl
	media-libs/libsdl
	media-libs/libogg
	media-libs/libvorbis
	net-misc/curl
	openal? ( media-libs/openal )"
RDEPEND="opengl? ( ${UIDEPEND} )
	!opengl? ( !dedicated? ( ${UIDEPEND} ) )"
DEPEND="${RDEPEND}
	app-text/dos2unix
	maps? ( app-arch/unzip )"
# compiling with multiple threads is not safe yet
MAKEOPTS=""
S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${MY_P}.tar.bz2
	unpack ${MY_DATA}
	if use maps ; then
		unpack wop_padpack.zip
		mv wop_padpack.pk3 wop
	fi
	mkdir sourcecode
	cd sourcecode
	unzip -q "../XTRAS/editing files/sourcecode.zip"
}

src_prepare() {
	cd ${WORKDIR}/sourcecode
	einfo "Fixing makefile..."
	sed -i \
		-e '/ LDFLAGS=/s:=:+=:' \
		Makefile \
		|| die "sed failed"
	einfo "Fixing source files..."
	find ${WORKDIR}/sourcecode -type f -iname "*.c" -exec dos2unix {} \; > /dev/null 2>&1 || die "Fixing c files failed"
	find ${WORKDIR}/sourcecode -type f -iname "*.h" -exec dos2unix {} \; > /dev/null 2>&1 || die "Fixing headers failed"
}

src_compile() {
	local arch

	if use amd64 ; then
		arch=x86_64
	elif use x86 ; then
		arch=i386
	fi

	cd ${WORKDIR}/sourcecode

	emake \
		ARCH=${arch} \
		BUILD_CLIENT=$(use opengl || ! use dedicated && echo 1 || echo 0) \
		BUILD_SERVER=$(use dedicated && echo 1 || echo 0) \
		DEFAULT_BASEDIR="${GAMES_DATADIR}"/${PN} \
		OPTIMIZE= \
		USE_CURL_DLOPEN=0 \
		USE_LOCAL_HEADERS=0 \
		USE_OPENAL=$(use openal && echo 1 || echo 0) \
		USE_OPENAL_DLOPEN=0 \
		|| die "emake failed"
}

src_install() {
	cd ${WORKDIR}/sourcecode/build/release-*
	if use opengl || ! use dedicated ; then
		newgamesbin wop-engine.* ${PN} || die "newgamesbin ${PN} failed"
		newicon "${WORKDIR}"/${MY_P}/misc/wop.png ${PN}.png || die "newicon failed"
		make_desktop_entry ${PN} "World of Padman"
	fi
	if use dedicated ; then
		newgamesbin wopded.* ${PN}-ded || die "newgamesbin ${PN}-ded failed"
	fi
	cd "${WORKDIR}"
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r wop || die "doins failed"
	cd "XTRAS"
	dohtml -r readme readme.html
	prepgamesdirs
}