pacmanager-3.ebuild

pacmanager-3.ebuild (text/plain), 1.62 KB, created by Fabio Rossi on 2011-06-30 16:34:28 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils rpm multilib

MY_PV="${PV}-2"

DESCRIPTION="PAC is a Perl/GTK Gnome replacement for SecureCRT/Putty/etc and more"
HOMEPAGE="http://sites.google.com/site/davidtv/"
SRC_URI="mirror://sourceforge/project/${PN}/pac-3.0/pac-${MY_PV}.noarch.rpm"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE=""

DEPEND=""
RDEPEND="${DEPEND}
	dev-lang/perl[ithreads]
	dev-perl/gtk2-gladexml
	dev-perl/Gtk2-Ex-Simple-List
	dev-perl/Gnome2-Vte
	dev-perl/gnome2-gconf
	dev-perl/crypt-cbc
	dev-perl/Crypt-Blowfish
	dev-perl/Net-ARP
	dev-perl/Expect
	dev-perl/Socket6
	dev-perl/yaml
	dev-perl/FreezeThaw
	dev-perl/UUID"

src_prepare() {
	# external dependencies dev-perl/Gnome2-Vte
	rm opt/pac/res/libgnome*

	# change the references to the final 'lib' and 'res' locations
	einfo "Fixing lib and ref locations..."
	find opt/pac/lib opt/pac/pac -type f | while read f
	do
		sed -i -e "s@\$RealBin[^']*\('\?\)/lib@\1/usr/$(get_libdir)/pacmanager@" "$f"
		sed -i -e "s@\$RealBin[^']*\('\?\)/res@\1/usr/share/pacmanager@" "$f"
	done
}

src_install() {
	insinto /usr/$(get_libdir)/${PN}
	doins -r opt/pac/lib/*
	insinto /usr/share/${PN}
	doins -r opt/pac/res/*

	dobin opt/pac/pac

	dodoc opt/pac/README
	doman usr/share/man/man1/pac.1

	insinto /usr/share/applications
	doins usr/share/applications/pac.desktop
	insinto /usr/share/pixmaps
	doins usr/share/pixmaps/pac.png
}

pkg_postinst()
{
	einfo "${PN} supports ssh, sftp, ftp, rdesktop, vncviewer, cu/tip/remote-tty"
	einfo "connections. Please install those tools if you need them."
}