# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v3
# $Header: $

EAPI="3"

inherit eutils mono

DESCRIPTION="information indexing software library for mono"
HOMEPAGE="http://incubator.apache.org/lucene.net/"
SRC_URI="mirror://apache/incubator/lucene.net/source/${PV}-incubating/Apache-Lucene.Net-${PV}-incubating.src.zip"

LICENSE="Apache-2.0 GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gac doc examples debug"

RDEPEND=">=dev-lang/mono-1.0"
DEPEND="${RDEPEND}
        app-arch/unzip
        >=dev-util/pkgconfig-0.20"


src_unpack() {
    mkdir -p "${S}"
    cd "${S}"
    unpack ${A}
}

src_prepare() {
    echo "Prepare assemblies for signing (creating strong names)"
    cp "${FILESDIR}/gentoo.snk" . || die
    
    local line1="[assembly: AssemblyKeyFile(@\"${S}/gentoo.snk\")]"
    local line2="[assembly: AssemblyDelaySign(false)]"

    local files=$(find . -iname 'AssemblyInfo.cs')

    for file in ${files}
    do
      echo "Patching: " ${file} 
      sed -i '/AssemblyDelaySign/d' ${file}
      sed -i '/AssemblyKeyFile/d' ${file}
      sed -i '/AssemblyKeyName/d' ${file}
      echo "${line1}" >> ${file} || die
      echo "${line2}" >> ${file} || die
    done
}

src_compile() {
    cd "${S}"

    local Configuration=Release
    if use debug; then
       Configuration=Debug
    fi

    xbuild /property:Configuration=${Configuration} \
        build/Lucene.Net.Core.sln \
        || die "build failed"
}

src_install() {

    insinto /usr/lib/nlucene/${PV}

    if use debug; then
        doins src/Lucene.Net/bin/Debug/Lucene.Net.dll
        doins src/Lucene.Net/bin/Debug/Lucene.Net.dll.mdb
    else
        doins src/Lucene.Net/obj/Release/Lucene.Net.dll
    fi

    if use gac; then
        egacinstall ${D}usr/lib/nlucene/${PV}/Lucene.Net.dll
    fi

    if use doc; then
        dodoc src/ABOUT.txt src/BUILD.txt src/CHANGES.txt src/HISTORY.txt
    fi

}