# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/metacity/metacity-2.34.0.ebuild,v 1.1 2011/04/05 13:27:22 eva Exp $

EAPI="3"
# debug only changes CFLAGS
GCONF_DEBUG="no"
GNOME_ORG_MODULE="metacity"

inherit gnome2 toolchain-funcs

DESCRIPTION="Keybinding files for Metacity and Mutter window managers"
HOMEPAGE="http://blogs.gnome.org/metacity/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
IUSE=""

RDEPEND="!<=x11-wm/metacity-2.34.0"
DEPEND="app-text/xmlstarlet
	dev-libs/glib:2
	>=dev-util/intltool-0.35
	dev-util/pkgconfig
	sys-devel/gettext"

src_prepare() {
	# doesn't use anything from config.h
	sed -e 's:#include "config.h":// #include "config.h":' \
		-i src/core/schema-bindings.c || die "schema-bindings.c sed failed"
}

src_configure() {
	# running gnome2_src_configure would be a senseless waste of processor time
	return
}

src_compile() {
	tc-export CC

	# po2 = files from po for LINGUAS we want
	# po3 = files from po2 with most of metacity internal strings removed
	mkdir po2 po3 || die "mkdir failed"
	for l in ${LINGUAS}; do
		mv po/${l}.po po2
	done

	cd src
	echo_exec ${CC} ${CFLAGS} -c core/schema-bindings.c \
		`pkg-config --cflags glib-2.0` -Iinclude
	echo_exec ${CC} ${LDFLAGS} schema-bindings.o \
		`pkg-config --libs glib-2.0` -o schema-bindings
	echo_exec ./schema-bindings metacity.schemas.in.in metacity.schemas.in

	for f in 50-metacity*.xml.in ; do
		# rename gettext package
		sed -e s:package=\"metacity\":package=\"${PN}\": \
			-i ${f} || die "${f} sed failed"
		# use currently empty po3 directory because gnome-control-center will
		# handle internationalization of keylist group names at runtime
		LC_ALL=C intltool-merge -x -u ../po3 ${f} ${f/xml.in/xml} ||
			die "intltool-merge failed"
	done
	LC_ALL=C intltool-merge -s -u ../po2 metacity.schemas.in metacity.schemas ||
		die "intltool-merge failed"

	# delete gconf schemas that are not keybindings
	xml ed -P -O -d '//schema[not(contains(key,"keybindings/"))]' \
		metacity.schemas > ${PN}.schemas || die "xmlstarlet failed"

	# extract gettext files for keylist group names
	cd ../po2
	for f in *.po ; do
		msggrep -N '../src/50-metacity-*.xml.in.h' ${f} -o ../po3/${f} ||
			die "msggrep failed"
		gmsgfmt ../po3/${f} -o ../po3/${f/.po/.gmo}
	done
}

src_install() {
	insinto /usr/share/gnome-control-center/keybindings
	doins src/50-metacity*.xml || die "doins failed"
	insinto /etc/gconf/schemas
	doins src/${PN}.schemas || die "doins failed"
	domo po3/*.gmo || die "domo failed"
}

echo_exec() {
	echo $@
	$@ || die
}