amun-0.1.9.ebuild

amun-0.1.9.ebuild (text/plain), 1.60 KB, created by Iván Atienza on 2011-05-12 20:09:34 UTC

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=3

PYTHON_DEPEND="2:2.4"
RESTRICT_PYTHON_ABIS="3.*"

inherit eutils python

DESCRIPTION="Low-interaction honeypot, capture autonomous spreading malware in an automated fashion."
HOMEPAGE="http://amunhoney.sourceforge.net/"
SRC_URI="mirror://sourceforge/project/${PN}honey/${PN}/${PN}-v${PV}/${PN}-v${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

S="${WORKDIR}/${PN}"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /dev/null ${PN}
}

pkg_info() {
	"${ROOT}"/opt/amun/amun_server.py --version
}

src_prepare() {
	einfo "This patch set runtime(after bind ports) privileges to user amun, default is root."
	epatch "${FILESDIR}/${PN}.conf.patch"
}

src_install() {
	insinto /opt
	doins -r "${S}" || die "install failed"
	exeinto /opt/${PN}
	doexe ${PN}_server.py
	dodoc AUTHORS CHANGELOG CREDITS INSTALL conf/${PN}_db.sql
	rm "${D}/opt/${PN}/AUTHORS" \
		"${D}/opt/${PN}/CHANGELOG" \
		"${D}/opt/${PN}/CREDITS" \
		"${D}/opt/${PN}/INSTALL" \
		"${D}/opt/${PN}/LICENSE" \
		"${D}/opt/${PN}/conf/${PN}_db.sql"
	doinitd "${FILESDIR}"/${PN}_server
	fowners -R ${PN}:${PN} /opt/${PN}
}

pkg_postinst() {
	python_mod_optimize /opt/${PN}
	ewarn "If you plan log to mysql you can create a database using:"
	ewarn "/usr/share/doc/"${P}"/"${PN}"_db.sql.bz2"
	ewarn " "
	ewarn "Modify as need /opt/"${PN}"/conf/log-mysql.conf and uncomment"
	ewarn "in /opt/amun/conf/"${PN}".conf log-mysql related lines"
}

pkg_postrm() {
	python_mod_cleanup /opt/${PN}
}